perl - ％hash和\％hash作为参数之间的区别？

Question

我目前正在尝试学习Perl，我注意到有时人们在将变量作为参数传递时会“转义”变量。我首先使用SQL::Abstract注意到了这一点:

my %hash = (
  'foo' => 'bar'
);
$db->insert('table', \%hash);

现在，在Perl中搜索“print_r”(PHP)等效项并看到人们推荐Data::Dumper，直到我看到一个使用print Dumper(\%hash);而不是print Dumper(%hash);的示例，我才能理解为什么人们会认为它们等效。

这:

my %hash = (
  key1 => 'value1',
  key2 => 'value2'
);
print Dumper(%hash);

输出此:

$VAR1 = 'key2';
$VAR2 = 'value2';
$VAR3 = 'key1';
$VAR4 = 'value1';

但是print Dumper(\%hash);输出以下内容:

$VAR1 = {
          'key2' => 'value2',
          'key1' => 'value1'
        };

有人可以确切解释这是什么以及正在发生什么吗？我在Perl书中找不到此书，甚至不知道在Google上搜索什么。谢谢。

Answer 1

借用Ether的注释-查看Perl References Tutorial，然后再查看语言规范中的Perl References Manual。或在命令行中使用perldoc perlreftut和perldoc perlref。

当您传递%hash时，Perl将可能大量的元素传递给被调用的函数，这些元素对应于键/值对。

当您传递\%hash时，Perl会传递对哈希的引用-本质上就是哈希的地址。

例如:

my %hash = ( Key1 => "Value1", Key2 => "Value2" );
sub counter
{
    printf "Count: %d\n", scalar(@_);
}
counter(%hash);
counter(\%hash);

产生:

Count: 4
Count: 1

您可以通过多种方式获取数据:

sub hashref
{
    my($ref) = @_;
    foreach my $key (keys %{$ref})
    {
         print "$key: $ref->{$key}\n";
    }
}

sub hashnonref
{
    my(%hash) = @_;
    foreach my $key (keys %hash)
    {
        print "$key: $hash{$key}\n";
    }
}

sub hashasarray
{
    my(@array) = @_;
    foreach my $value (@array)
    {
         print "Value: $value\n";
    }
}

hashref(\%hash);   # Same data as before
print "\n";
hashnonref(%hash);
hashasarray(%hash);

额外的输出:

Key2: Value2
Key1: Value1

Key1: Value1
Key2: Value2
Value: Key2
Value: Value2
Value: Key1
Value: Value1