在列表中对Erlang记录进行排序？

Question

我在erlang中有一条记录:

-record(myrec,
    { 
      id = 0,
      price = 0,
      quantity = 0
    }).

然后，我有了一个要按ID和价格排序的记录列表，按降序和升序排序，其中价格是第一个键，如果两个记录的价格相同，我要按ID排序。

我如何为此定义一个乐趣？

我是Erlang的新手:)

谢谢，
尼斯巴士

Answer 1

这是比到目前为止建议的解决方案更短的解决方案。首先定义您的记录:

1> rd(myrec, {id=0, price=0, quantity=0}).
myrec

然后让我们发明其中的三个:

2> A = #myrec{id=1, price=10, quantity=2}, B = #myrec{id=2, price=4, quantity=3}, C = #myrec{id=3, price=10, quantity=1}.
#myrec{id = 3,price = 10,quantity = 1

现在我们需要一个比较功能。这是解决方案更短的地方。 Erlang可以按元组的出现顺序对它们进行比较，因此，如果我们要按价格排序，然后按id排序，我们只需要比较{PriceA, IdA} < {PriceB, IdB}形式的两个元组:

3> F = fun(X, Y) -> {X#myrec.price, X#myrec.id} < {Y#myrec.price, Y#myrec.id} end.
#Fun<erl_eval.12.113037538>

并将其插入lists:sort/2:

4> lists:sort(F, [C,B,A]).
[#myrec{id = 2,price = 4,quantity = 3},
 #myrec{id = 1,price = 10,quantity = 2},
 #myrec{id = 3,price = 10,quantity = 1}]

现在，该订单为[B, A, C]，并且您的列表已排序。

请注意，如果要改为按降序ID排序，则可以通过如下反转元组中的ID来欺骗它:

5> G = fun(X, Y) -> {X#myrec.price, Y#myrec.id} < {Y#myrec.price, X#myrec.id} end.
#Fun<erl_eval.12.113037538>
6> lists:sort(G, [C,B,A]).                                                       
[#myrec{id = 2,price = 4,quantity = 3},
 #myrec{id = 3,price = 10,quantity = 1},
 #myrec{id = 1,price = 10,quantity = 2}]

给我们[B, C, A]。这对读者来说并不明显，因此您最好记录下来，或者在这种情况下使用Dustin的解决方案。这里介绍的解决方案的优点是不需要嵌套。通过在比较中的任何一个元组中设置元素，您几乎可以根据需要对它们进行比较，而无需花费更长的时间。