clojure - 用于处理 seq 的步行与 map

Question

据我了解，walk 和 map 都将函数应用于 seq。 (walk 还允许应用 outer 函数后处理)。但是，使用一个而不是另一个的惯用情况是什么？

Answer 1

将函数应用于 seq 是 map 的工作。当您必须遍历和递归进入整个结构时，请使用 walk。
walk的一些例子可以在 ClojureDocs 找到，也可在 REPL 中找到，例如(user/clojuredocs clojure.walk/postwalk) .许多示例都是教学性的，可以而且应该使用 map 来完成。或 for (有时 reduce )在实践中。
walk 的典型用例是当您希望递归处理嵌套结构时。这可能有用的一些示例是 clojure.walk命名空间本身，例如看 (source clojure.walk/keywordize-keys) . [注意，如果您想迭代或随意处理它，请使用 zipper (或 tree-seq 用于一些更简单的迭代情况)。]

另一个想到的例子是解释解析树:

(require '[clojure.walk :as w])

(def t [+ [* [- 6 2] [/ 9 3]] [* 2 [+ 7 8]]])

(w/postwalk #(if (and (coll? %) (fn? (first %))) (apply (first %) (next %)) %) t)
;=> 42

如果，例如，替换 fn?，也许有用与 allowed-fn?等来评估 edn表达式，而不是调用太强大的 eval 编译器:

(eval t) ;=> [#<core$_PLUS_ ... ] 

糟糕，表单是列表，而不是向量:

(def s (w/postwalk #(if (coll? %) (apply list %) %) t))
s ;=> (#<core$_PLUS_ ... )
(eval s) ;=> 42

啊，注意这里 walk 的另一种用法-- 递归地将结构从嵌套向量更改为嵌套列表。

一个反复思考的例子:

(require '[clojure.walk :as w])

(def s1 (range 8))
s1 ;=> (0 1 2 3 4 5 6 7)
(map inc s1)
;=> (1 2 3 4 5 6 7 8)
(w/postwalk #(if (number? %) (inc %) %) s1)
;=> (1 2 3 4 5 6 7 8)

(def s2 (partition 2 s1))
s2 ;=> ((0 1) (2 3) (4 5) (6 7))
(map (partial map inc) s2)
;=> ((1 2) (3 4) (5 6) (7 8))
(w/postwalk #(if (number? %) (inc %) %) s2)
;=> ((1 2) (3 4) (5 6) (7 8))

(def s3 (partition 2 s2))
s3 ;=> ((0 1) (2 3) (4 5) (6 7))
(map (partial map (partial map inc)) s3)
;=> (((1 2) (3 4)) ((5 6) (7 8)))
(w/postwalk #(if (number? %) (inc %) %) s3)
;=> (((1 2) (3 4)) ((5 6) (7 8)))

(def s4 (partition 2 s3))
s4 ;=> ((((0 1) (2 3)) ((4 5) (6 7))))
(map (partial map (partial map (partial map inc))) s4)
;=> ((((1 2) (3 4)) ((5 6) (7 8))))
(w/postwalk #(if (number? %) (inc %) %) s4)
;=> ((((1 2) (3 4)) ((5 6) (7 8))))