regex - 在 Perl 中使用正则表达式列出来自另一个 Perl 脚本的变量

Question

关于如何从 Perl 文件中获取所有标量和数组，我的想法是:

open (InFile, "SomeScript.pl");
@InArray = <InFile>;
@OutArray = {};
close (InFile);
$ArrayCount = @InArray;
open (OutFile, ">outfile.txt");
for ($x=0; $x<=$ArrayCount; $x++){
$Testline = @InArray[$x];

if($Testline =~ m/((@|\$)[A-Z]+)/i){
    $Outline = "$1\n";  
    push @OutArray, $Outline;
}
}
print OutFile @OutArray;
close(OutFile);

...这很有效。问题是，如果一行中出现多个变量，它只会获取第一个变量。一个例子可能是:

$FirstVar = $SecondVar + $ThirdVar;

脚本只会抓取 $FirstVar 并输出到文件。这可能仍然有效，因为 $SecondVar 和 $ThirdVar 必须在其他地方初始化，然后继续行才有任何意义。我想规则的异常(exception)是同时初始化多个变量的行。

真实 Perl 代码中的示例能否破坏此脚本？ 另外，如何从同一行中获取符合我的正则表达式条件的多个项目？

Answer 1

不要那样做

你不能真正用正则表达式解析 Perl，所以我什至不会尝试。
如果不实际运行它，您甚至无法正确解析它，但您可以接近 PPI .

perl-变量.pl

#! /usr/bin/env perl
use strict;
use warnings;
use 5.10.1;

use PPI;
use PPI::Find;

my($filename) = (@ARGV, $0); # checks itself by default

my $Doc = PPI::Document->new($filename);
my $Find = PPI::Find->new( sub{
  return 0 unless $_[0]->isa('PPI::Token::Symbol');
  return 1;
});

$Find->start($Doc);
while( my $symbol = $Find->match ){
  my $raw = $symbol->content;
  my $var = $symbol->symbol;
  if( $raw eq $var ){
    say $var;
  } else {
    say "$var\t($raw)";
  }
}
print "\n";

my @found = $Find->in($Doc);
my %found;
$found{$_}++ for @found;

say for sort keys %found;

针对自身运行它，产生:

$filename
@ARGV
$0
$Doc
$filename
$Find
@_  ($_)
$Find
$Doc
$symbol
$Find
$raw
$symbol
$var
$symbol
$raw
$var
$var
@found
$Find
$Doc
%found
%found  ($found)
$_
@found
%found

$0
$Doc
$Find
$_
$filename
$found
$raw
$symbol
$var
%found
@ARGV
@found