emacs - 如何在 Emacs 模式行中显示总行数

Question

默认的 Emacs 模式行仅显示当前行号及其相对于总行号的百分比。我如何让它也显示总行数？

Answer 1

这可能有点棘手，因为如果您一直更新行数并且有一个大缓冲区，它可能会使 Emacs 有点 react 迟钝，因为它一遍又一遍地计算行数。我写这个是为了采取一种懒惰的方法来计数:它只在第一次读入文件或保存/恢复文件后才这样做。如果缓冲区被修改，它不会对行数说谎，它在您再次保存之前不会显示。

(defvar my-mode-line-buffer-line-count nil)
(make-variable-buffer-local 'my-mode-line-buffer-line-count)

(setq-default mode-line-format
              '("  " mode-line-modified
                (list 'line-number-mode "  ")
                (:eval (when line-number-mode
                         (let ((str "L%l"))
                           (when (and (not (buffer-modified-p)) my-mode-line-buffer-line-count)
                             (setq str (concat str "/" my-mode-line-buffer-line-count)))
                           str)))
                "  %p"
                (list 'column-number-mode "  C%c")
                "  " mode-line-buffer-identification
                "  " mode-line-modes))

(defun my-mode-line-count-lines ()
  (setq my-mode-line-buffer-line-count (int-to-string (count-lines (point-min) (point-max)))))

(add-hook 'find-file-hook 'my-mode-line-count-lines)
(add-hook 'after-save-hook 'my-mode-line-count-lines)
(add-hook 'after-revert-hook 'my-mode-line-count-lines)
(add-hook 'dired-after-readin-hook 'my-mode-line-count-lines)

您可能需要调整 mode-line-format当然，为了适合你的口味，以上是我个人更喜欢的。