delphi - 创建表单时不会调用 TPicture 属性的 Set 方法

Question

这是我的组件整体结构:

• 我的组件
  • 属性类别:TCollection(属于 TCategory)
    • TCategory
      • 属性图标:TPicture读FIcon写SetIcon；
      • 属性示例:整数读取 FExample 写入 SetExample；
      • (其他类别属性...)
  • (其他属性...)

在 IDE 的对象检查器中，我选择一张图片，它已成功序列化(我在表单 View 中将其检查为文本)。我在 SetIcon 方法上设置了一个断点，当我编译并运行应用程序时，它根本没有被调用。同时，SetExample 被正确调用。

TPicture 属性有什么问题？

P.S: Set 方法在 IDE 中调用，但在运行时不调用。

这是代码的 MCVE:

unit MCVE;

interface

uses
  System.SysUtils, System.Classes, Vcl.Controls, Graphics, Dialogs;

type
  TMyCollectionItem = class(TCollectionItem)
  private
    FIcon: TPicture;
    procedure SetIcon(const Value: TPicture);
  public
    constructor Create(Collection: TCollection); override;
  published
    property Icon: TPicture read FIcon write SetIcon;
  end;

  TMyCollection = class(TCollection)
  end;

  TMCVE = class(TCustomControl)
  private
    FCollection: TMyCollection;
    procedure SetCollection(const Value: TMyCollection);
  public
    constructor Create(AOwner: TComponent); override;
  published
    property MyCollection: TMyCollection read FCollection write SetCollection;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TMCVE]);
end;

{ TMyCollectionItem }

constructor TMyCollectionItem.Create(Collection: TCollection);
begin
  inherited;
  FIcon := TPicture.Create;
end;

procedure TMyCollectionItem.SetIcon(const Value: TPicture);
begin
  ShowMessage('SetIcon is called!');
  FIcon.Assign(Value);
end;

{ TMCVE }

constructor TMCVE.Create(AOwner: TComponent);
begin
  inherited;
  FCollection := TMyCollection.Create(TMyCollectionItem);
end;

procedure TMCVE.SetCollection(const Value: TMyCollection);
begin
  FCollection := Value;
end;

end.

Answer 1

对于Integer、Boolean、Double等简单类型，流式传输按照您描述的方式运行。流框架读取值，并调用属性 setter 。

对于像 TPicture 这样更复杂的类型，情况不会这样发生。流框架无法调用属性 setter 。为了做到这一点，它需要获得一个完全形成的TPicture。它事先并不知道如何做到这一点。

因此，流框架会调用属性的 getter 来获取组件构造函数创建的 TPicture 实例。然后以 .dfm 文件中存储的 TPicture 状态进行流传输。

碰巧的是，TPicture 没有已发布的属性。图片数据保存到 .dfm 文件中名为 Data 的属性下。那么，它从何而来。答案就在重写的 DefineProperties 方法中。代码如下所示:

procedure TPicture.DefineProperties(Filer: TFiler);

  function DoWrite: Boolean;
  begin
    // .... code removed for brevity
  end;

begin
  Filer.DefineBinaryProperty('Data', ReadData, WriteData, DoWrite);
end;

WriteData 和 ReadData 方法执行流式处理。

所以，回顾一下。您询问为什么在图片属性中进行流式传输时未调用 TPicture 属性的 setter 。它不会被调用，因为您在构造函数中创建的图片对象在其属性中流动。