我提前为我的问题的长度道歉!我正在尝试自动为我们的事件构建论文时间表。论文和作者数据在电子表格中提供(我可怜的同事目前使用它逐行手动剪切和粘贴到 Word 文档中)。此电子表格包含我制定计划所需的所有信息,列在一致命名的列中,但可以按任何顺序排列。有点像这样(但真正的论文标题不会方便地编号):
Jack Doe - Co-Author - Penn State University - Aerodynamics - Aerodynamics Paper I
John Doe - Co-Author - Penn State University - Acoustics - Acoustics Paper I
John Smith - Co-Author - University of VA - Acoustics - Acoustics Paper I
Jane Doe - Main Author - Penn State University - Acoustics - Acoustics Paper I
Bob Smith - Main Author - GA Tech - Acoustics - Acoustics Paper II
Jack Smith - Main Author - University of MD - Acoustics - Acoustics Paper III
Jill Smith - Co-Author - University of MD - Acoustics - Acoustics Paper III
Bob Doe - Main Author - Penn State University - Aerodynamics - Aerodynamics Paper I
我的目标是转换电子表格数据,以便论文按 session (即声学、空气动力学)分组和排序,然后按论文标题(即声学论文 I、声学论文 II),然后按每所大学的作者。问题是任何给定论文的“主要作者”必须列在第一位,然后是同一所学校的合著者(如果有的话),然后是其他大学的合著者。其他共同作者可以按任何顺序排列,但也必须按大学分组。
所以拿原来的例子来说,应该是这样的:
ACOUSTICS
Acoustics Paper I
Jane Doe, John Doe, Penn State University; John Smith, University of VA
Acoustics Paper II
Bob Smith, GA Tech
Acoustics Paper III
Jack Smith, Jill Smith, University of MD
AERODYNAMICS
Aerodynamics Paper I
Bob Doe, Jack Doe, Penn State University
我快到了,但我只能到达
ACOUSTICS
Acoustics Paper I
Jane Doe, Penn State University; John Doe, Penn State University; John Smith, University of VA;
Acoustics Paper II
Bob Smith, GA Tech;
Acoustics Paper III
Jack Smith, University of MD; Jill Smith, University of MD;
AERODYNAMICS
Aerodynamics Paper I
Bob Doe, Penn State University; Jack Doe, Penn State University;
我们正在使用 ACF 2016。我正在做的(我的代码在下面)是使用 cfspreadsheet 将电子表格读入查询对象。然后我按 session 对输出进行分组,然后使用嵌套的 cfoutputs 按标题进行分组。
然后,因为我想不出任何其他方法来识别每篇论文的主要作者并将他们放在第一位,所以我遍历该论文的所有作者并添加一个标志来识别他们,然后使用 arraySort 对其进行排序。请注意,我不能简单地按作者类型 DESC 排序,因为还有另一种类型,“presenting author”,为简洁起见,我省略了它 (ha)。有时主要作者也可以是主讲作者,所以这种类型就是“主要作者主讲作者”。
无论如何,我都会遍历排序后的数组。
以下是我到目前为止尝试过的方法。我坚持让大学只为每个作者列表显示一次。我已经尝试在我的 authorArray 循环中放置另一个循环,但我不知道要索引或循环什么,所以它最终只是在每个作者姓名之后输出大学名称。我尝试过使用多维数组,甚至使用查询的查询来尝试构建一个漂亮的有序数据结构。但我显然做错了,因为我总是被按大学对作者分组所困扰。
我当然会很感激任何提示或提示!请注意,我无法更改最初使用此电子表格的要求。然而,一旦我得到它,我就可以使用我需要的信息做任何事情以获得所需的输出。所以我完全愿意做出任何改变或重新考虑我的整个方法。下面的代码是我得到的最接近的代码。
非常感谢大家!这是我目前使用的:
<cfoutput query="queryPapers" group="PrimarySession">
#PrimarySession#
<cfoutput group="Title">
<p>#Title#</p>
<cfset authorArray = arrayNew(1)>
<cfoutput>
<cfset authorStruct = structNew()>
<cfset authorStruct.firstName = AuthorFirstName>
<cfset authorStruct.lastName = AuthorLastName>
<cfset authorStruct.institution = AuthorInstitution>
<cfset authorStruct.authorType = AuthorType>
<cfif findNoCase("Main", AuthorType)>
<cfset authorStruct.authorMain = "A">
<cfelse>
<cfset authorStruct.authorMain = "B">
</cfif>
<cfset arrayAppend(authorArray, authorStruct)>
<cfscript>
arraySort(
authorArray,
function (e1, e2) {
return compare(e1.authorMain, e2.authorMain);
}
);
</cfscript>
</cfoutput>
<cfloop index="i" from="1" to="#arrayLen(authorArray)#">
#authorArray[i].firstName# #authorArray[i].lastName#,
#authorArray[i].institution#;
</cfloop>
</cfoutput>
</cfoutput>
下面是上面代码的一些实际输出:
Dynamic Stall Investigations
Sergey Smith,* University of Maryland; Tobias Lersdorf, German University; Pascal Marceau, University of Maryland;
我正努力去
Dynamic Stall Investigations
Sergey Smith,* Pascal Marceau, University of Maryland; Tobias Lersdorf, German University
非常感谢阅读!
最佳答案
您的代码走在正确的轨道上,但我认为您有点过于复杂了。您可以简化嵌套的 <cfoutput>
使用以下代码片段进行处理。
<!--- Nested output loop for displaying required result --->
<cfoutput query="queryPapers" group="PrimarySession">
<strong>#Ucase(PrimarySession)#</strong><br />
<cfoutput group="Title">
<i>#Title#</i><br />
<cfoutput group="AuthorInstitution">
<cfoutput>
#AuthorFirstName# #AuthorLastName#,
</cfoutput>
#AuthorInstitution#; <!--- display institution once per group --->
</cfoutput>
<br /><br /> <!--- double-space after each title group --->
</cfoutput>
</cfoutput>
可以通过添加另一层组嵌套并将其显示在额外嵌套组的页脚中来解决只显示大学一次的问题。
您在确保主要作者始终排在第一位方面遇到的问题应该在您的预处理中得到解决。为此,请使用您现有的 if/else 逻辑(“A”代表主要作者,否则为“B”)并将其作为额外列添加到您的查询中。这样你就可以在你的
order by
中使用它输出循环之前的子句。
更新
所以我在发布我的第一次修订后意识到存在一个小的逻辑缺陷。它没有出现的原因是因为在使用上面的示例数据时,主要作者很方便地总是属于“标题”组中按字母顺序排在第一位的大学。在看到额外的示例输出后我意识到了这一点,我将这些行添加到我的代码示例中,但它也错误地显示如下。
Dynamic Stall Investigations
Sergey Smith, University of Maryland; Tobias Lersdorf, German University; Pascal Marceau, University of Maryland;
解决方案是使用现有的 authorMain 列(主要作者为 A
,否则为 B
)并添加另一个值 A2
对于与主要作者属于同一所大学的非主要作者。棘手的部分是您必须检查另一行中的值以确定何时设置 A2
.我能想到的最佳解决方案是在添加最初填充的 authorMain 列之后立即添加这两个代码块。
<!--- Sort query so "Main Author" is first within PrimarySession and Title --->
<cfquery name="queryPapers" dbtype="query">
select * from queryPapers
order by
PrimarySession,
Title,
AuthorMain
</cfquery>
<!--- Loop through above and update NON "Main-Author" rows "A2" if they have same University as "A" rows --->
<cfset MainInstitution = "">
<cfloop query="queryPapers">
<cfif queryPapers.authorMain eq "A">
<cfset MainInstitution = queryPapers.AuthorInstitution>
<cfelse>
<cfif MainInstitution eq queryPapers.AuthorInstitution>
<cfset QuerySetCell(queryPapers, "authorMain", "A2", queryPapers.currentRow)>
</cfif>
</cfif>
</cfloop>
首先按 PrimarySession、Title 和 AuthorMain 排序,然后遍历记录集并使用 A2
更新行如果非主要作者与主要作者在同一所大学,请使用 MainInstitution
进行跟踪多变的。此解决方案生成正确的结果,同时允许所有其他代码保持不变。
关于coldfusion - 使用 ColdFusion (2016) 遍历电子表格数据并对输出进行分组,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/48858286/