import - 在另一个AppleScript中导入AppleScript方法吗？

Question

有没有办法在其他AppleScript中使用已定义的AppleScript方法，这些方法引用与导入类似的原始AppleScript(例如PHP)？

我写了一个方法来设置Skype的状态和心情文本:

on setSkypeStatus(status, mood_text)
    tell application "System Events"
        set skypeRunning to count (every process whose name is "Skype")

        if skypeRunning > 0 then --only set status if skype is running
            tell application "Skype"
                set myStatus to "SET USERSTATUS " & status
                set myMood to "SET PROFILE MOOD_TEXT " & mood_text

                send command myStatus script name "AppleScript"
                send command myMood script name "AppleScript"
                return skypeRunning
            end tell
        else
            return skypeRunning
        end if
    end tell
end setSkypeStatus

现在，我正在搜索类似 import skype_methods.scpt 的东西。有没有这样的功能。我和Google没什么关系。

Answer 1

将另一个脚本作为库导入的一种方法是定义一个属性，该属性通过将库作为脚本对象加载来初始化。然后，您可以使用tell命令来调用库函数。

property pSkypeLibrary : load script POSIX file "/Users/sakra/Desktop/skype_methods.scpt"

tell pSkypeLibrary
    setSkypeStatus("status", "mood")
end tell