d - D 编程语言中的 "yield return"等价物是什么？

Question

这是一个简单的 C# 生成器。

    IEnumerable<int> Foo()
    {
        int a = 1, b = 1;
        while(true)
        {
            yield return b;
            int temp = a + b;
            a = b;
            b = temp;
        }
    }

如何在 Digital Mars D 中编写类似的生成器？

(问题是关于yield return语句)

谢谢!

更新。
那很有意思。因为我只是生成一个数学序列，所以使用 recurrence可能是一个不错的选择。

auto fib = recurrence!("a[n-1] + a[n-2]")(1, 1);

foreach (e; take(fib, 10)) // <- prints first ten numbers from the sequence
{ 
    writeln(e); 
}

Answer 1

D 中没有确切的等价物。以下是一些粗略的等价物:

使用 opApply 风格的内部迭代。但是，这不允许以锁步方式迭代两个迭代器:

struct Foo {
    int opApply(int delegate(ref int) dg) {
        int a = 1, b = 1;
        int result;
        while(true) {
            result = dg(b);
            if(result) break;
            int temp = a + b;
            a = b;
            b = temp;
        }

        return result;
    }
}

void main() {
    // Show usage:
    Foo foo;
    foreach(elem; foo) {
        // Do stuff.
    }
}

使用范围。这些在某些情况下稍微难写，但非常有效并且允许锁步迭代。这也可以用 foreach 迭代。循环，与 opApply 完全一样版本:

struct Foo {
    int a = 1, b = 1;

    int front() @property {
        return b;
    }

    void popFront() {
        int temp = a + b;
        a = b;
        b = temp;
    }

    // This range is infinite, i.e. never empty.
    enum bool empty = false;

    typeof(this) save() @property { return this; }
}

如果您 真的需要协程风格的东西，你可以使用 core.thread.Fiber 将范围和 opApply 组合在一起，但您可能会发现 range 或 opApply 几乎一直都在做您需要的事情。