sql - 禁用Oracle中的所有表约束

Question

如何使用单个命令禁用 Oracle 中的所有表约束？ 这可以针对单个表、表列表或所有表。

Answer 1

最好避免写出临时假脱机文件。使用 PL/SQL block 。您可以从 SQL*Plus 运行它或将其放入包或过程中。与 USER_TABLES 的连接是为了避免 View 约束。

您不太可能真的想禁用所有约束(包括 NOT NULL、主键等)。您应该考虑将constraint_type 放入WHERE 子句中。

BEGIN
  FOR c IN
  (SELECT c.owner, c.table_name, c.constraint_name
   FROM user_constraints c, user_tables t
   WHERE c.table_name = t.table_name
   AND c.status = 'ENABLED'
   AND NOT (t.iot_type IS NOT NULL AND c.constraint_type = 'P')
   ORDER BY c.constraint_type DESC)
  LOOP
    dbms_utility.exec_ddl_statement('alter table "' || c.owner || '"."' || c.table_name || '" disable constraint ' || c.constraint_name);
  END LOOP;
END;
/

再次启用约束有点棘手 - 您需要先启用主键约束，然后才能在外键约束中引用它们。这可以通过对constraint_type 使用ORDER BY 来完成。 'P' = 主键，'R' = 外键。

BEGIN
  FOR c IN
  (SELECT c.owner, c.table_name, c.constraint_name
   FROM user_constraints c, user_tables t
   WHERE c.table_name = t.table_name
   AND c.status = 'DISABLED'
   ORDER BY c.constraint_type)
  LOOP
    dbms_utility.exec_ddl_statement('alter table "' || c.owner || '"."' || c.table_name || '" enable constraint ' || c.constraint_name);
  END LOOP;
END;
/