excel - 检索当前本地计算机相对于 UTC 时间的小时数(使用 VBA)

Question

人们在多个时区使用我的项目。

为了转换时间戳，使用 VBA 仅检索本地计算机相对于 UTC 的当前小时数的最快方法是什么？

Answer 1

这里有两种现成的方法来检索当前相对于 UTC 时间的小时数，仅此而已:

方法一:使用“任何”API

Option Explicit

Function hoursOffsetFromUTC() As Single
    'returns current #hours difference between UTC & Local System Time
    'On Error GoTo uError
    Dim xmlHTTP As Object, strUTC As String, dtUTC As Date
    Set xmlHTTP = CreateObject("MSXML2.XMLHTTP")
    xmlHTTP.Open "GET", "https://maps.googleapis.com/maps/api/" & _
        "timezone/json?location=" & Int(Rnd() * 99) & ",0&timestamp=" & Int(Rnd() * 99), False
    xmlHTTP.send 'send randomized reqeust to avoid cached results
    strUTC = Mid(xmlHTTP.getResponseHeader("date"), 6, 20)
    Set xmlHTTP = Nothing
    dtUTC = DateValue(strUTC) + TimeValue(strUTC)
    hoursOffsetFromUTC = Round((Now() - dtUTC) * 48, 0) / 2 'nearest 0.5
    Exit Function
uError:
    MsgBox "Couldn't get UTC time." & vbLf & vbLf & _
        "Err#" & Err & ": " & Err.Description, vbExclamation, "Error!"
End Function

• 用法示例:MsgBox hoursOffsetFromUTC

---

方法二:使用Windows API

Private Type SYSTEMTIME
    wYear As Integer
    wMonth As Integer
    wDayOfWeek As Integer
    wDay As Integer
    wHour As Integer
    wMinute As Integer
    wSecond As Integer
    wMilliseconds As Integer
End Type

Private Type TIME_ZONE_INFORMATION
    Bias As LongPtr
    StandardName(0 To 31) As Integer
    StandardDate As SYSTEMTIME
    StandardBias As LongPtr
    DaylightName(0 To 31) As Integer
    DaylightDate As SYSTEMTIME
    DaylightBias As LongPtr
End Type

Private Declare PtrSafe Function GetTimeZoneInformation Lib "kernel32" _
    (lpTimeZoneInformation As TIME_ZONE_INFORMATION) As Long

Function hoursOffsetFromUTC_Win() As Single
    Dim TZI As TIME_ZONE_INFORMATION
    If GetTimeZoneInformation(TZI) = 2 Then
        hoursOffsetFromUTC_Win = 0 - ((TZI.Bias + TZI.DaylightBias) / 60)
    Else
        hoursOffsetFromUTC_Win = 0 - (TZI.Bias / 60)
    End If
End Function

• 用法示例:MsgBox hoursOffsetFromUTC_Win

---

方法一代码较少，但需要互联网连接。它使用随机数调用 Google API 以避免缓存，并忽略响应正文，它获取响应 header 中返回的请求日期并将其与本地系统时间进行比较。 (可以使用任何在 header 中返回当前 UTC/GMT 的 API。)

方法二需要声明两种类型和一个外部函数，但无需互联网连接即可运行，使用 Windows 内部 kernel32 API 的功能。

---

转换时间戳:

• 要将数字 Unix/纪元时间戳转换为“Excel Time ”:

  ( 时间戳/86400 ) + 25569 = ExcelTime

• 或者相反，从 Excel 到纪元时间戳:

  ( ExcelTime - 25569 ) * 86400 = 时间戳

(这些不包括时区调整，因此您可以根据需要添加/减去它。)

---

更多信息:

• 维基百科:Unix Time & Digital Timestamps

• EpochConverter:Epoch & Unix Timestamp Conversion Tools

• 奇普· PIL 森:Time Zones And Daylight Savings Time (Windows API)

• 堆栈溢出:Convert between arbitrary timezones (区域→区域)

• 微软支持:How to use times and dates in Excel