sparql - 使用 DBPedia 加载所有人员以及一些数据

Question

我是第一次使用 DBpedia。我想下载人员数据集中的所有人员以及 commonName、nationality、birthDate 和knownFor 属性(我认为最终我会使用某种脚本语言将其粘贴到 Excel 电子表格中)。

这是我第一次尝试通过查询来完成这项工作，但它不起作用。我尝试将它与我在互联网上看到的其他代码拼凑在一起。有谁知道如何解决这一问题？谢谢

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/> 

SELECT ?person ?commonName ?nationality ?knownFor ? birthDate
WHERE {
    ?person a type:Person .
    ?person prop:commonName ?commonNameFilter(lang(?commonName) = 'en') .
    ?person prop:nationality ?nationality(lang(?nationality) = 'en') .
    ?person prop:knownFor ?knownFor(lang(?knownFor) = 'en') .
    ?person prop:birthDate ?birthDate .
}

编辑:新版本的代码:返回通用名(带有非英语重复项)。仍然缺少其他属性。

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/ontology/>

SELECT DISTINCT * WHERE {
    ?person a dbpedia-owl:Person ;  
              dbpedia-owl:commonName ?commonName . FILTER(lang(?commonName) = 'en')
}
LIMIT 30

Answer 1

首先，您的查询有很多语法问题:

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/> 
            ^ you probably want to use the dbpedia-owl properties which are 
            # in <http://dbpedia.org/ontology/>
SELECT ?person ?commonName ?nationality ?knownFor ? birthDate
                                                   ^ space between ? and varname
WHERE {
    ?person a type:Person .
    ?person prop:commonName ?commonNameFilter(lang(?commonName) = 'en') .
                                       ^ This needs to be "?commonName . FILTER(..."
                                       # and the same thing applies to your other 
                                       # filters
    ?person prop:nationality ?nationality(lang(?nationality) = 'en') .
    ?person prop:knownFor ?knownFor(lang(?knownFor) = 'en') .
    ?person prop:birthDate ?birthDate .
}

增量构建其中一些查询会更容易，因为这样您就可以找出某些资源实际上具有哪些属性，然后您可以进一步扩展查询。公共(public)端点的编号为 predefined namespaces ，并且使用它们将使其他人更容易阅读您的查询。因此，您可以从询问人员开始:

SELECT * WHERE {
    ?person a dbpedia-owl:Person .
}
LIMIT 10

SPARQL results

看到它起作用了，您可以查看一些返回的实例，并看到它们具有 dbpedia-owl:commonName 属性，然后扩展查询:

SELECT * WHERE {
    ?person a dbpedia-owl:Person ;  
              dbpedia-owl:commonName ?commonName .
}
LIMIT 10

SPARQL results

使用dbpedia-owl:birthDate属性来扩展它是很容易的。我在查看的实例上没有看到国籍谓词，因此我不确定您的国籍查询基于什么。虽然我看到了 knownFor 属性的一些使用，但我在很多实例中都没有看到它，因此如果将其设为必需属性，则会排除很多人。不过，从长远来看，这种渐进方法可能会对您有所帮助。

查找属性

虽然可浏览本体提供了一种查找类的好方法，但我不确定是否有这样好的方法来查找属性。然而，你可以用蛮力的方式做一些事情。例如，要查找实际用于 Person 的所有属性，您可以运行如下查询。 (注意:此查询需要一段时间才能执行，因此如果您使用它，您可能应该下载结果。)

select distinct ?p where {
  [] a dbpedia-owl:Person ;
     ?p [] .
}

SPARQL results

我会注意到 dbpedia-owl:nationality 确实出现在该列表中。

要获取所有内容的所有属性，您可以 download the ontology ，然后运行如下查询:

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix owl: <http://www.w3.org/2002/07/owl#>
select * where { 
  { ?p a owl:ObjectProperty }
  UNION 
  { ?p a owl:DatatypeProperty }
}

我使用 Jena 的 ARQ 在本地运行此操作:

$ arq --query properties.sparql --data dbpedia_3.8.owl
----------------------------------------------------------------------------
| p                                                                        |
============================================================================
| <http://dbpedia.org/ontology/regionServed>                               |
| <http://dbpedia.org/ontology/coachedTeam>                                |
| <http://dbpedia.org/ontology/legalForm>                                  |
| <http://dbpedia.org/ontology/goldenCalfAward>                            |
| <http://dbpedia.org/ontology/composer>                                   |
| <http://dbpedia.org/ontology/owningOrganisation>                         |
| <http://dbpedia.org/ontology/branchFrom>                                 |
| <http://dbpedia.org/ontology/iso6393Code>                                |
...
| <http://dbpedia.org/ontology/classification>                             |
| <http://dbpedia.org/ontology/bgafdId>                                    |
| <http://dbpedia.org/ontology/currencyCode>                               |
| <http://dbpedia.org/ontology/onChromosome>                               |
| <http://dbpedia.org/ontology/course>                                     |
| <http://dbpedia.org/ontology/frequentlyUpdated>                          |
| <http://dbpedia.org/ontology/distance>                                   |
| <http://dbpedia.org/ontology/volume>                                     |
| <http://dbpedia.org/ontology/description>                                |
----------------------------------------------------------------------------

这不会提供 rdfs:domain 和 rdfs:range，但您也可以要求提供这些，或者仅提供 rdfs 的那些属性: range dbpedia-owl:Person (但请注意，这不会获取可以使用 Person 的所有属性，因为范围可能或多或少具体):

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix owl: <http://www.w3.org/2002/07/owl#>
prefix dbpedia-owl: <http://dbpedia.org/ontology/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>

select ?p ?range where { 
  { ?p a owl:ObjectProperty }
  UNION 
  { ?p a owl:DatatypeProperty }

  ?p rdfs:domain dbpedia-owl:Person ; rdfs:range ?range .
}


$ arq --query properties.sparql --data dbpedia_3.8.owl | head
--------------------------------------------------------------------------------------------------------
| p                                           | range                                                  |
========================================================================================================
| dbpedia-owl:restingPlacePosition            | <http://www.w3.org/2003/01/geo/wgs84_pos#SpatialThing> |
| dbpedia-owl:opponent                        | dbpedia-owl:Person                                     |
| dbpedia-owl:employer                        | dbpedia-owl:Organisation                               |
| dbpedia-owl:hometown                        | dbpedia-owl:Settlement                                 |
| dbpedia-owl:militaryBranch                  | dbpedia-owl:MilitaryUnit                               |
| dbpedia-owl:school                          | dbpedia-owl:EducationalInstitution                     |
| dbpedia-owl:ethnicity                       | dbpedia-owl:EthnicGroup                                |
...
| dbpedia-owl:sex                             | xsd:string                                             |
| dbpedia-owl:hipSize                         | xsd:double                                             |
| dbpedia-owl:individualisedPnd               | xsd:nonNegativeInteger                                 |
| dbpedia-owl:weddingParentsDate              | xsd:date                                               |
| dbpedia-owl:birthName                       | xsd:string                                             |
| dbpedia-owl:networth                        | xsd:double                                             |
| dbpedia-owl:birthYear                       | xsd:gYear                                              |
| dbpedia-owl:bustSize                        | xsd:double                                             |
| dbpedia-owl:description                     | xsd:string                                             |
--------------------------------------------------------------------------------------------------------