emacs - 使用emacs，如何交换2个窗口的位置

Question

我在 Emacs 中打开了 2 个窗口，我想交换它们的位置。

即考虑在源文件上方有一个 REPL，我想交换它们的位置，以便 REPL 位于源文件下方。

我还想保留窗口的大小

Answer 1

我无耻地从Steve Yegge's .emacs偷了这个

(defun swap-windows ()
  "If you have 2 windows, it swaps them." 
  (interactive)
  (cond ((not (= (count-windows) 2)) (message "You need exactly 2 windows to do this."))
        (t
         (let* ((w1 (first (window-list)))
                (w2 (second (window-list)))
                (b1 (window-buffer w1))
                (b2 (window-buffer w2))
                (s1 (window-start w1))
                (s2 (window-start w2)))
           (set-window-buffer w1 b2)
           (set-window-buffer w2 b1)
           (set-window-start w1 s2)
           (set-window-start w2 s1)))))

在 Gentoo 上的 Emacs 23.1.1 上测试。这确实保留了窗口大小。

我还发现这个更干净一些。

(defun transpose-windows ()
  (interactive)
  (let ((this-buffer (window-buffer (selected-window)))
        (other-buffer (prog2
                          (other-window +1)
                          (window-buffer (selected-window))
                        (other-window -1))))
    (switch-to-buffer other-buffer)
    (switch-to-buffer-other-window this-buffer)
    (other-window -1)))

还在 Emacs 23.1.1 上进行了测试