macos - 用于运行检测显示器的 Applescript

Question

当我将外部显示器插入 Macbook 并唤醒它时，显示器的分辨率通常是错误的。在使用 Mountain Lion 之前，我能够运行以下 applescript 来检测显示器:

tell application "System Preferences" to activate
tell application "System Events"
    tell process "System Preferences"
        click menu item "Displays" of menu "View" of menu bar 1
        tell button "Detect Displays" of window 1 to click
    end tell
end tell
tell application "System Preferences" to quit

但是，在 10.8 中，“检测显示”按钮要求您按 Option 键才能显示它，因此脚本会给出以下错误:

error "System Events got an error: Can’t get button \"Detect Displays\" of window 1 of process \"System Preferences\"." number -1728 from button "Detect Displays" of window 1 of process "System Preferences"

我的 applescript 技能还不够初级，而且我的 google-fu 还没有让我偶然找到答案。

如何修改脚本以单击现在隐藏的检测显示按钮？

Answer 1

试试这个...

tell application "System Preferences"
    activate
    reveal pane "com.apple.preference.displays"
end tell

delay 0.5

tell application "System Events"
    tell process "System Preferences"
        try --don't even consider not using a try block!
            key down option
            delay 0.2
            click button "Detect Displays" of window 1
            delay 0.2
            key up option
        on error --logging out is the only other way to clear these
            key up option
        end try
    end tell
end tell