assembly - MASM:在 .data 声明中使用当前位置计数器 ($)

Question

我遇到了有关 MASM 中当前位置计数器的问题。

这是我的汇编代码，我使用 Visual Studio 2013 Express 进行汇编

.386
.model flat,stdcall
.stack 8192
ExitProcess proto,dwExitCode:dword

.data
ptr1 DWORD $
ptr2 DWORD $
ptr5 DWORD $


.code
main proc
    mov eax, $
    mov eax, $
    invoke ExitProcess,0
main endp
end main

在我看来，我认为ptr1、ptr2和ptr5应该有自己的位置值。

但事实上这是不正确的。

在 Debug模式下，变量显示相同的结果。

ptr1、ptr2、ptr5具有相同的地址，并且它们之间没有偏移。

使用 $ 声明时有什么问题？

Answer 1

您的问题似乎是 MASM 中的一个错误(或者正如 Microsoft 可能所说的那样，是一个“功能”)。问题不在于 DWORD 指令未生成目标代码，也不在于它们未推进汇编器的位置计数器。如果前者为真，那么它们根本不会出现在可执行文件中，如果后者为真，它们都将具有相同的地址。

问题在于，当在某些上下文中使用时，MASM 错误地使用当前段开头的偏移量(在生成的目标文件中)作为 $ 的值，而不是当前位置计数器。数据定义。以下代码基于您的示例演示了这一点(并显示了一个简单的解决方案):

        .386
        PUBLIC  ptr1, ptr2, ptr5, ptr6, len

_DATA   SEGMENT
        mov     eax, $
        mov     eax, $
ptr1    DWORD   $
ptr2    DWORD   $
ptr5    DWORD   OFFSET $
ptr6    DWORD   ptr6
len     DWORD   $ - ptr1
        mov     eax, $
_DATA   ENDS

        END

以下是 IDA 如何反汇编 MASM 针对上述汇编代码创建的目标文件:

.data:00000000 $$000000:
.data:00000000                 mov     eax, offset $$000000
.data:00000005 $$000005:
.data:00000005                 mov     eax, offset $$000005
.data:0000000A ptr1            dd offset $$000000
.data:0000000E ptr2            dd offset $$000000
.data:00000012 ptr5            dd offset $$000000
.data:00000016 ptr6            dd offset ptr6
.data:0000001A len             dd 16
.data:0000001E $$00001E:
.data:0000001E                 mov     eax, offset $$00001E

您会注意到 mov eax, $ 指令显示 DWORD 指令正确地推进了位置计数器。您还会注意到，ptr1、ptr2 和 ptr5 均已使用 $$000000 进行了初始化，该值位于段的开始，完全忽略了先前的 MOV 指令和 DWORD 指令都已提前了位置计数器的事实。

另一方面，MASM 确实正确评估 $ - ptr1。这将计算 ptr1 和当前位置计数器之间的距离，即 16，即前四个 DWORD 指令的总长度(以字节为单位)。这意味着至少在这种情况下，MASM 使用正确的 $ 值。

最后，该示例展示了如何解决此问题。只需使用命名标签而不是 $，如 ptr6 DWORD ptr6 行中所示。这会导致汇编器正确生成一个初始化为指向自身的指针。