我有一个优化模型,我尝试针对不同的输入文件求解该模型,我将其准确地称为“在不同场景下求解模型”。因此,我需要一个循环来从 Excel 中读取每个不同工作表的数据。让我说清楚:例如,在下图中,我们有一个包含 4 个场景的数据,每个场景的工作表名称都在逐一增加
这些数据必须作为每个场景的表格来读取,就像在 Excel 文件中一样。
我尝试用循环读取不同 Excel 工作表中的数据。我可以在 Gams 中做到这一点吗?
在 GAMS 中,我可以从 Excel 中获取数据,如下所示,但这仅适用于一种情况。我想制作一个 GAMS 代码,在循环语句中从 Excel 工作表中读取所有场景的数据
Table n(t,b)
$call =xls2gms r="nonbooked!A2:I9" i="excelveri.xlsx" o="nbooked.inc"
$include nbooked.inc
;
最佳答案
GAMS put_utility ( https://www.gams.com/latest/docs/UG_Put.html#UG_Put_PutUtil ) 和工具 GDXXRW ( https://www.gams.com/latest/docs/T_GDXXRW.html ) 是解决这个问题的关键。这是一个独立的(希望是不言自明的)示例:
set i / i1*i3 /
j / j1*j4 /
sheets / Sheet1*Sheet3 /;
parameter data(i,j);
file fx; put fx;
* To make this example self contained, first prepare some data (using same mechanics as the reading)
loop(sheets,
* Create random data
data(i,j) = uniformInt(0,9);
* Write data to GDX
execute_unload 'data.gdx', data;
* Write GDX data to excel
put_utility 'exec' / 'gdxxrw.exe data.gdx par=data rng=' sheets.tl:0 '!a1';
);
* Clear data to start fresh
data(i,j) = 0;
* Load data
loop(sheets,
* Write Excel data to GDX
put_utility 'exec' / 'gdxxrw.exe data.xlsx par=data rng=' sheets.tl:0 '!a1';
* Load data from GDX
execute_load 'data.gdx', data;
* Work with the data, just display as an example
display data;
);
希望对您有所帮助, 卢茨
关于excel - GAMS 中的循环用于在 Excel 中生成场景,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/42859215/