haskell - 如何使用 Lenses 来表示 `mapM` 和 `concat` 以连接 IO 操作的结果？

Question

我正在想办法结合traverseOf与 >>=以这样的方式允许以下内容。

TLDR；普通 Haskell 中的一个简单示例如下所示，但使用数据结构深处的透镜。

λ> fmap concat $ mapM ((return :: a -> IO a) . const ["he", "he"]) ["foo", "bar", "baz"]
["he","he","he","he","he","he"]

这是带有示例的冗长解释

data Foo = Foo [Bar] deriving Show
data Bar = Baz | Qux Int [String] deriving Show

makePrisms ''Foo
makePrisms ''Bar

items :: [Foo]
items = [Foo [Baz], Foo [Qux 1 ["hello", "world"], Baz]]

-- Simple replacement with a constant value
constReplace :: [Foo]
constReplace = over (traverse._Foo.traverse._Qux._2.traverse) (const "hehe") items
-- λ> constReplace
-- [Foo [Baz],Foo [Qux 1 ["hehe","hehe"],Baz]]

-- Doing IO in order to fetch the new value. This could be replacing file names
-- with the String contents of the files.
ioReplace :: IO [Foo]
ioReplace = (traverse._Foo.traverse._Qux._2.traverse) (return . const "hehe") items
-- λ> ioReplace
-- [Foo [Baz],Foo [Qux 1 ["hehe","hehe"],Baz]]

-- Replacing a single value with a list and concatenating the results via bind
concatReplace :: [Foo]
concatReplace = over (traverse._Foo.traverse._Qux._2) (>>= const ["he", "he"]) items
-- λ> concatReplace
-- [Foo [Baz],Foo [Qux 1 ["he","he","he","he"],Baz]]

-- Same as the previous example, but the list comes from an IO action
concatIoReplace :: IO [Foo]
concatIoReplace = (traverse._Foo.traverse._Qux._2) (return . (>>= const ["he", "he"])) items
-- λ> concatIoReplace
-- [Foo [Baz],Foo [Qux 1 ["he","he","he","he"],Baz]]

现在最后一个例子就是问题所在，因为我通过更改正在应用的函数来进行了一些作弊。在 concatReplace我能够使用>>= (感谢 #haskell-lens channel 上的乐于助人的人)实现 concatMap类似的功能。但在我的真实代码中，我拥有的功能是 String -> IO [String] ，看起来像这样

correctConcatIo :: IO [Foo]
correctConcatIo = (traverse._Foo.traverse._Qux._2) (>>= (return . const ["he", "he"])) items

但是这个例子不再进行类型检查。我需要的基本上是将 ioReplace 中的逻辑组合在一起和concatReplace以某种方式，我将能够应用类型 String -> IO [String] 的函数到包含 [String] 的数据结构.

Answer 1

只有当字符串已经存在于列表中时，您才能将其替换为 [String](考虑尝试将 [Int] 放回到 _Qux._1 中)，因此您必须将函数转换为[String]->IO [String] 并使用您已经演示过的某种方法替换整个列表:

concatMapM f l = fmap concat (mapM f l)

doIOStuff s = return ['a':s, 'b':s]

concatIO :: IO [Foo]
concatIO = (traverse._Foo.traverse._Qux._2) (concatMapM doIOStuff) items

您甚至可以将 concatMapM 组合到末尾以获得 LensLike 类型的内容，但它不够灵活，无法与大多数镜头组合器一起使用。