assembly - 代码在哪里可以更有效地检查输入字符是否为元音？

Question

此组装项目读取按键并以特定颜色输出它们。当按下一个元音时，它会改变文本的颜色，直到按下另一个元音为止，直到按下 ESC 键为止。颜色以某种模式呈现，这就是为什么 I SUB 8 在循环结束时。我只是想让它更有效率。我尝试将所有比较语句合并为一行，但没有成功。

INCLUDE        Macros.inc
INCLUDE     Irvine32.inc
INCLUDELIB  Irvine32.lib
.386
.STACK 4096
ExitProcess PROTO, dwExitCode:DWORD

.DATA
key       BYTE ?     
colorCode BYTE 5
max       BYTE 13

.CODE
main PROC

FindKey:
mov EAX, 50
call Delay

call ReadKey 
jz FindKey

MOV key, AL 
     cmp key, 75h
     JE UP
     CMP key, 6Fh
     JE UP
     CMP key, 69h
     JE UP
     CMP key, 65h
     JE UP
     CMP key, 61h
     JE UP
     CMP key, 55h
     JE UP
     CMP key, 4Fh
     JE UP
     CMP key, 49h
     JE UP
     CMP key, 45h
     JE UP
     CMP key, 41h
     JE UP
     CMP dx,VK_ESCAPE
     JE OVER

     COLOR:   
          MOVZX EAX, (black * 16) + colorCode
          CALL SetTextColor 
          MOV AL, key
          call WriteChar
          jmp FindKey

          UP: 
               CMP colorCode, 13
               JE RESET
               INC colorCode
               jmp COLOR

               RESET:
                    sub colorCode, 8
                    jmp COLOR    

     OVER:
     CALL Crlf
     INVOKE ExitProcess, 0

main ENDP
END main

Answer 1

如果您对高效的 x86 代码感兴趣，请参阅 x86 标签维基中的链接。有很多好东西，尤其是。阿格纳雾的指南。

您在 key 中有 AL ，但您的 cmp 指令都使用内存操作数。 cmp al, imm8 有一个特殊的操作码，所以 cmp al, 75h 只是一个 2 字节的指令。使用绝对位移来寻址 key 会产生更长的指令。此外，cmp mem,imm 不能与条件跳转进行宏融合。每个insn都需要加载端口。

其余代码看起来很可疑，好像它使用了过多的内存操作数，并且缩进很奇怪。 ( UP 看起来像是 COLOR 块的一部分，但实际上在 COLOR 的末尾有一个无条件跳转，所以它不会落入 UP 。)

当然，一长串 cmp/je 远非最佳，因为所有 je 目标都是相同的。您不需要弄清楚哪个键实际匹配。

您可以用于此类检查的一种策略是查看 al 是否在正确的范围内，然后将其用作位图的索引。

编译器对 (Godbolt compiler explorer) 使用此策略 switch or multi-condition if like this 。这就是为什么我们大部分时间都使用编译器而不是手动编写 asm 的原因:它们知道很多聪明的技巧并且可以在适用的地方应用它们。我们得到 1<<c 的开关，但 if 实际上编译为 bt 与 GCC。 (不过，GCC9 有一个回归，其中开关编译为跳转表。)

有关无符号比较技巧 (ja .non_alphabetic) 的说明和有效循环的示例，请参阅 my answer on another ASCII question。

    MOV   [key], AL    ; store for later use

    or    al,  20h     ; lowercase (assuming an alphabetic character)
    sub   al, 'a'      ; turn the ascii encoding into an index into the alphabet
    cmp   al, 'z'
    ja  .non_alphabetic

    mov   ecx, (1<<('a'-'a')) | (1<<('e'-a')) | (1<<('i'-a')) | (1<<('o'-a')) | (1<<('u'-a'))   ; might be good to pull this constant out and use an EQU to define it
    ; movzx eax, al    ; unneeded except for possible partial-register issues
    bt    ecx, eax      ; test for the letter being set in the bitmap
    jc  UP              ; jump iff al was a vowel
.non_alphabetic:
    CMP dx,VK_ESCAPE    ; this test could be first.
    JE OVER

( bt 屏蔽其输入，仅使用低位作为“移位计数”，因此您实际上并不需要 movzx 。但是如果您确实需要避免某些 uarches 或其他东西上的部分寄存器停顿，请使用 movzx edx, al 而不是 movzx eax, al 因为-elimination 仅适用于不同的寄存器。)

这是明显更少的指令和更少的分支，因此它使用更少的分支预测器条目。

不要将 bt 的常量保留在内存中:bt mem,reg 很慢，因为它可以访问不同地址的疯狂 CISC 语义是位索引高于操作数大小。当 bt 与寄存器第一个操作数一起使用时，它仅屏蔽位索引。
bt 的替代方法是执行 if(mask & 1 << (key - 'a')) :

    movzx ecx, al      ; avoid partial-reg stall or false dep on ecx that you could get with mov ecx,eax or mov cl,ca respectively
    mov   eax, 1
    shl   eax, cl      ; eax has a single set bit, at the index
    test  eax, 1<<('a'-'a') | 1<<('e'-a') | 1<<('i'-a') | 1<<('o'-a') | 1<<('u'-a')
    jnz  .vowel

这是更多的 uops，即使 test/jnz 可以进行宏融合，因为在英特尔 Sandbridge 系列 CPU 上，可变计数移位是 3 uops。 (同样，疯狂的 CISC 语义会减慢速度)。

或者右移掩码而不是创建 1<<c 。您甚至可以通过将掩码右移 1 位来安排跳过 test al,1，因此您想要分支的位被 shr 移入 CF。
但是在 Nehalem 和更早版本上，读取可变计数移位的标志结果会使前端停止，直到移位从后端退出，而在 SnB 系列上，对于可变计数移位，它仍然是 3 uop。

由于评论正在讨论 SSE:

    ; broadcast the key to all positions of an xmm vector, and do a packed-compare against a constant
    ; assuming  AL is already zero-extended into EAX
    imul    eax, eax, 0x01010101    ; broadcast AL to EAX
    movd    xmm0, eax
    pshufd  xmm0, xmm0, 0    ; broadcast the low 32b element to all four 32b elements
    pcmpeqb xmm0, [vowels]   ; byte elements where key matches the mask are set to -1, others to 0
    pmovmskb eax, xmm0
    test    eax,eax
    jnz   .vowel


section .rodata:
  align 16
  vowels: db 'a','A', 'e','E'
          db 'i','I', 'o','O'
          db 'u','U', 'a','a'
    times 4 db 'a'            ; filler out to 16 bytes avoiding false-positives

字节广播(SSSE3 pshufb 或 AVX2 vpbroadcastb)而不是双字广播(pshufd)将避免 imul。或者在广播之前使用 or eax,0x20 这样我们就不需要每个元音的大小写版本，只需要小写。然后我们可以用 movd + punpcklbw + pshufd 或类似的东西进行广播。

这需要从内存中加载一个常量，而不是一个 32 位位图，它可以有效地在指令流中作为立即数，因此即使它只有一个分支，这也可能没有那么好。 (请记住，位图版本需要在非字母上进行分支，然后在元音上进行分支)。