haskell - 字符串和 [a] 实例

Question

作为练习，我决定在 Haskell 中实现一个 Blank 类型类(其中 blank 为空时为 true，False 或仅包含空格的String)。我简单地开始了:

class Blank a where
  blank :: a -> Bool

instance Blank Bool where
  blank = not

instance Blank [a] where
  blank = null

当我去实现String实例时:

instance Blank String where
  blank [] = True
  blank (' ':xs) = blank xs
  blank ('\t':xs) = blank xs
  blank ('\n':xs) = blank xs
  blank ('\r':xs) = blank xs
  blank _ = False

我收到了错误消息:

Illegal instance declaration for `Blank String'
  (All instance types must be of the form (T t1 ... tn)
   where T is not a synonym.
   Use -XTypeSynonymInstances if you want to disable this.)
In the instance declaration for `Blank String'

我很确定这是因为 [a] 和 String 是多余的，即 String ([Char]) 是 [a] 的更具体实例。

有没有办法解决这个问题并定义一个更具体的实例(即[Char])？

Answer 1

有一个标准技巧可以以优雅的方式实现您想要的目标。 如果您考虑要做什么，您应该记住一个使用它的标准且常用的类:Show。

也许你从来没有想过 show [1,2,3] == "[1, 2, 3]" 而 show "hello"== "\"hello\""，但问题是一样的。解决这个问题的方法是向 Show 类添加一个 showList::[a] -> ShowS 操作，为其添加默认定义，然后提供通用列表的实例。

在你的情况下，你想要这样的东西:

import Data.Char(isSpace)

class Blank a where
  blank :: a -> Bool
  blankList :: [a] -> Bool
  blankList = null

instance Blank a => Blank [a] where
  blank = blankList

instance Blank Char where
  blank = isSpace

  blankList [] = True
  blankList (' ':xs) = blankList xs
  blankList ('\t':xs) = blankList xs
  blankList ('\n':xs) = blankList xs
  blankList ('\r':xs) = blankList xs
  blankList _ = False

这样，每当您在列表上调用 blank 时，都会调用相应的 blankList 方法。使用的方法是列表的元素实例提供的方法，因此Char实例可以定义blankList来返回True 当列表非空但仅包含空格等时，而其他实例可以简单地使用 null 的默认实现。

此实现的缺点是您必须将 String 的操作放入 Char 的实例中。然而，没有办法解决这个问题:在 Haskell 98/2010 中，类型构造函数和类只能有一个实例，因此一旦定义了 Blank [a] 实例，就无法使用 拥有其他实例[]，其中包括String。

将 Blank [a] 的实例替换为 Blank a => Blank [a] 的实例可让您仅为 [] 定义一个实例 但是它的行为会根据Blank a的实例而变化，因此您可以特殊情况String。

<小时/>

如前所述，另一种解决方案是根本不处理 String。您始终可以定义:

newtype MyString = MyString String

然后使用MyString代替String。