Haskell getContents 等待 EOF

Question

我想等到用户输入以 EOF 终止，然后将其全部输出。这不是 getContents 应该做的吗？每次用户按回车键时都会输出以下代码，我做错了什么？

import System.IO

main = do
  hSetBuffering stdin NoBuffering
  contents <- getContents
  putStrLn contents

Answer 1

根本问题是 getContents 是 Lazy IO 的实例。这意味着 getContents 生成一个可以像普通 Haskell 值一样进行计算的 thunk，并且仅在强制时才执行相关 IO。

contents 是一个 putStr 尝试打印的惰性列表，它会强制列表并导致 getContents 尽可能多地读取。 putStr 然后打印强制的所有内容，并继续尝试强制列表的其余部分，直到它到达 []。由于 getContents 可以读取越来越多的流 - 确切的行为取决于缓冲 - putStr 可以立即打印越来越多的流，为您提供您所看到的行为。

虽然此行为对于非常简单的脚本很有用，但它将 Haskell 的求值顺序与可观察效果联系起来——这是它从未打算做的事情。这意味着精确控制内容的部分内容何时被打印是很尴尬的，因为你必须打破正常的Haskell抽象并准确理解事物是如何被评估的。

这会导致一些潜在的不直观的行为。例如，如果您尝试获取输入的长度(并且实际上使用它)，则在打印它之前会强制列表，从而为您提供所需的行为:

main = do
  contents <- getContents
  let n = length contents
  print n
  putStr contents

但是如果将 print n 移到 putStr 之后，您将返回到原始行为，因为 n 不会被强制执行，直到 < em>打印输入后(即使n在使用putStr之前仍然定义):

main = do
  contents <- getContents
  let n = length contents
  putStr contents
  print n

通常情况下，这种事情不是问题，因为它不会改变代码的行为(尽管它会影响性能)。惰性 IO 只是通过穿透抽象层将其带入正确的领域。

这也为我们提供了如何解决您的问题的提示:我们需要某种方法在打印之前强制内容。正如我们所看到的，我们可以使用 length 来做到这一点，因为 length 在计算其结果之前需要遍历整个列表。我们可以使用 seq 来代替打印它，它强制左侧表达式与右侧表达式同时求值，但会丢弃实际值:

main = do
  contents <- getContents
  let n = length contents
  n `seq` putStr contents

同时，这仍然有点难看，因为我们使用 length 只是为了遍历列表，而不是因为我们真正关心它。我们真正想要的是一个仅仅遍历列表来评估它的函数，而不做任何其他事情。令人高兴的是，这正是 deepseq 所做的(对于许多数据结构，而不仅仅是列表):

import Control.DeepSeq
import System.IO

main = do
  contents <- getContents
  contents `deepseq` putStr contents