excel - 根据唯一条件的出现顺序对 Excel 中的重复文本值进行排名

Question

在 Excel 中，我的结果数据按类似于下面的列表排序。我正在寻找一个公式来对“类别”列进行排名。我提出了以下似乎可行的方法，但没有考虑“独特”的 RaceID 列。

={COUNTIF(Class,"<"&C2)+SUM(IF(C2=$C$2:C2, 1, 0))-(SUMPRODUCT(--(C2>C$2:C$11))+1)}

其中“Class”指的是“C:C”。

不幸的是，即使 Daniel 是 RaceID 0002 的比赛获胜者，这也会在单元格 E7 中产生 A 级结果“4”。

第五列是所需的输出。

Col A     Col B          Col C    Col D     Col E
RaceID    Overall Pos    Class    Name      Class rank
0001      1              A        Jack      1
0001      2              A        Matt      2
0001      3              A        Daniel    3
0001      4              B        Gordon    1
0001      5              B        Phillip   2
0002      1              A        Daniel    1
0002      2              A        Matt      2
0002      3              B        Günther   1
0002      4              B        Gordon    2
0002      5              A        Jack      3

我需要的是能够将此公式扩展到仅当 RaceID 值与当前行匹配时才排名。我确信这应该不会那么困难，但我正在努力完成公式。

Answer 1

如果我的理解是正确的，那么这个非数组公式就可以了:

=COUNTIFS(A:A,A2,B:B,"<"&B2,C:C,C2)+1

编辑

如果您的 Excel 不支持 COUNTIFS 那么这个公式也可以:

{=SUM(IF(($A$1:INDEX(A:A,MATCH("zzz",D:D))=A2)*($C$1:INDEX(C:C,MATCH("zzz",D:D))=C2),$B$1:INDEX(B:B,MATCH("zzz",D:D))<B2)*1)+1}

This is an array formula and must be confirmed with ctrl+shift+enter.