MASM 提供了 SEGMENT 指令。该指令需要几个参数。 use
参数可以采用值FLAT
。我不清楚这个值的作用。
Microsoft docs将其指定为可接受的值,但不尝试描述它:
use
USE16, USE32, FLAT
这本书The Art of Assembly Language Programming在线提供的文档提到了它,但称其超出范围,并建议阅读 MASM 程序员指南:
The
use32
andflat
operands tell MASM to generate code for a 32 bit segment. Since this text does not deal with protected mode programming we will not consider these options. See the MASM Programmer's Guide for more details.
在 Microsoft 的 MASM 6.1 程序员指南中,在描述 SEGMENT
指令的部分中,提到了 FLAT
值,但从未描述其效果:
The size attribute can be USE16, USE32, or FLAT.
FLAT 操作数对 SEGMENT 指令有何影响?
最佳答案
对于大多数用途,在段伪指令中使用 FLAT 关键字时,其含义与 USE32 相同。 USE32 和 FLAT 关键字都表明该段可以大于 64K,并且该段中组装的任何指令都应使用 32 位编码而不是 16 位编码。不同之处在于汇编器对 CS 寄存器的假设。通常,SEGMENT 指令会生成隐式 ASSUME CS:xxx
指令,其中 xxx
是段的名称,但对于 FLAT,它会生成隐式 ASSUME CS:平坦
。
ASSUME 指令告诉汇编器哪些段被加载到哪些段寄存器中,以便它可以在需要时自动使用正确的段覆盖。在大多数 32 位操作系统使用的平面内存模型中,只有一个 4 GB 段。告诉汇编器它可以假设段寄存器是 FLAT,这告诉汇编器程序中定义的所有段都可以通过该段寄存器访问。例如ASSUME DS:FLAT
表示所有段都可以通过DS寄存器访问。另一方面,ASSUME DS:_DATA
表示 DS 寄存器只能用于访问 _DATA 段,而不能用于访问任何其他段。
您可以通过组装以下代码来查看此行为:
_DATA SEGMENT PUBLIC USE32
var DD ?
_DATA ENDS
_TEXT SEGMENT PUBLIC PARA 'CODE' FLAT
mov eax, [zero]
mov [var],eax
ASSUME DS:FLAT
mov eax, [zero]
mov [var],eax
ASSUME CS:_TEXT
ASSUME DS:_DATA
mov eax, [zero]
mov [var],eax
zero DD 0
_TEXT ENDS
END
如果反汇编生成的目标文件,您会在前两条指令中看到以下内容:
00000000: 2E A1 00 00 00 00 mov eax,dword ptr cs:[zero]
00000006: 2E A3 00 00 00 00 mov dword ptr cs:[var],eax
对于这两条指令,汇编器必须使用 CS 段覆盖 (2E
) 才能访问 zero
和 var
。这是因为,虽然汇编器知道 CS 可用于访问所有段,包括 _TEXT
和 _DATA
,但它不知道任何其他段寄存器可用于访问这些片段。
这是它在 ASSUME DS:_FLAT
指令之后为接下来的两条指令生成的代码:
0000000C: A1 00 00 00 00 mov eax,dword ptr [zero]
00000011: A3 00 00 00 00 mov dword ptr [var],eax
现在汇编器知道 CS 和 DS 都可以用来访问所有段。由于使用 DS 访问 zero
和 var
不需要段覆盖,因此它使用 DS 而不是 CS,从而导致指令更短。
最后,在 ASSUME DS:_DATA
和 ASSUME CS:_TEXT
指令之后的最后两条指令,显示了如果不使用 FLAT 关键字,汇编器将生成的代码完全:
00000016: 2E A1 00 00 00 00 mov eax,dword ptr cs:[zero]
0000001C: A3 00 00 00 00 mov dword ptr [var],eax
在这种情况下,汇编器假定 CS 只能用于访问 _TEXT,而 DS 只能用于访问 _DATA。它必须使用 CS 覆盖来访问 zero
,而它只能通过 DS 访问 var
,这不需要段覆盖。
请注意,如果您将上面示例代码中 SEGMENT 指令中的 FLAT 更改为 USE32,则第一条指令最终会使用 CS 覆盖,但第二条指令会生成以下错误:
error A2074:cannot access label through segment registers
这是因为虽然汇编器知道它可以通过 CS 寄存器访问 _TEXT,但它不知道可以使用任何段寄存器来访问 _DATA。
如果您在代码开头使用 .MODEL FLAT
指令,则不必担心这些问题。然后 USE32 和 FLAT 在段指令中具有完全相同的效果,因为每个段寄存器都被假定为 FLAT。
关于assembly - FLAT 操作数对 SEGMENT 指令的影响?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/45124341/