B+ 树的叶节点链接在一起。将 B+ 树的指针结构视为有向图,它不是循环的。但是忽略指针的方向并将其视为链接在一起的无向叶节点会在图中创建循环。
在 Haskell 中,如何将叶子构造为父内部节点的子节点,并同时构造来自相邻叶子节点的下一个链接。如何使用 Haskell 的代数数据类型做到这一点?看来 Haskell ADT 总体上使得循环类结构难以表达。
最佳答案
这是(不可变/“可变”重建/zipperable)ADT表示的一个想法(涉及不可变vectors):
module Data.BTree.Internal where
import Data.Vector
type Values v = Vector v
type Keys k = Vector k
data Leaf k v
= Leaf
{ _leafKeys :: !(Keys k)
, _leafValues :: !(Values v)
, _leafNext :: !(Maybe (Leaf k v)) -- @Maybe@ is lazy in @Just@, so this strict mark
-- is ok for tying-the-knot stuff.
-- , _leafPrev :: !(Maybe (Leaf k v))
-- ^ for doubly-linked lists of leaves
}
type Childs k v = Vector (BTree k v)
data Node k v
= Node
{ _nodeKeys :: !(Keys k)
, _nodeChilds :: !(Childs k v)
}
data BTree k v
= BTreeNode !(Node k v)
| BTreeLeaf !(Leaf k v)
newtype BTreeRoot k v
= BTreeRoot (BTree k v)
这应该是内部的,这样原始构造函数、访问器或模式匹配的不当使用就不会破坏树。
可以添加Keys
、Values
、Childs
长度控制(通过运行时检查或可能通过GADT等) .
对于界面:
module Data.BTree ( {- appropriate exports -} ) where
import Data.Vector
import Data.BTree.Internal
-- * Building trees: "good" constructors.
keys :: [k] -> Keys k
keys = fromList
values :: [v] -> Values v
values = fromList
leaves :: [Leaf k v] -> Childs k v
leaves = fromList . fmap BTreeLeaf
leaf :: Keys k -> Values v -> Maybe (Leaf k v) -> Leaf k v
-- or
-- leaf :: Keys k -> Values v -> Maybe (Leaf k v) -> Maybe (Leaf k v) -> Leaf k v
-- for doubly-linked lists of leaves
leaf = Leaf
node :: Keys k -> Childs k v -> BTree k v
node ks = BTreeNode . Node ks
-- ...
-- * "Good" accessors.
-- ...
-- * Basic functions: insert, lookup, etc.
-- ...
然后是这种树:
可以构建为
test :: BTree Int ByteString
test = let
root = node (keys [3, 5]) (leaves [leaf1, leaf2, leaf3])
leaf1 = leaf (keys [1, 2]) (values ["d1", "d2"]) (Just leaf2)
leaf2 = leaf (keys [3, 4]) (values ["d3", "d4"]) (Just leaf3)
leaf3 = leaf (keys [5, 6, 7]) (values ["d5", "d6", "d7"]) Nothing
in root
该技术称为 "tying the knot" 。叶子可以循环:
leaf1 = leaf (keys [1, 2]) (values ["d1", "d2"]) (Just leaf2)
leaf2 = leaf (keys [3, 4]) (values ["d3", "d4"]) (Just leaf3)
leaf3 = leaf (keys [5, 6, 7]) (values ["d5", "d6", "d7"]) (Just leaf1)
或双向链接(假设_leafPrev
和相应的leaf
函数):
leaf1 = leaf (keys [1, 2]) (values ["d1", "d2"]) (Just leaf2) (Just leaf3)
leaf2 = leaf (keys [3, 4]) (values ["d3", "d4"]) (Just leaf3) (Just leaf1)
leaf3 = leaf (keys [5, 6, 7]) (values ["d5", "d6", "d7"]) (Just leaf1) (Just leaf2)
<小时/>
使用 mutable vectors 也可以实现完全可变的表示和 mutable references :
type Values v = IOVector v
type Keys k = IOVector k
type Childs k v = IOVector (BTree k v)
, _leafNext :: !(IORef (Maybe (Leaf k v)))
等等,基本相同,但是使用IORef
和IOVector
,在IO
monad中工作。
关于haskell - 如何在Haskell中实现B+树?,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/20309501/