vb.net - OleDbException 未处理......UPDATE 语句中的语法错误

Question

我在调试时遇到错误，请有人帮忙... 下面是代码:

 Private Sub UpdateToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles UpdateToolStripMenuItem.Click
    If MsgBox("Save Changes?", MsgBoxStyle.Question + MsgBoxStyle.YesNo, "WARNING") = MsgBoxResult.Yes Then
        Dim oleDC As New OleDbCommand
        With oleDC
            .Connection = conn
            .CommandText = "UPDATE tblPatientsRecord SET Names='" & txtNames.Text & _
        "',Licensenumber='" & txtLicensenumber.Text & _
        "',Address='" & txtAddress.Text & _
        "',Fullname='" & txtFullname.Text & _
        "',Birthday='" & txtBase.Text &
        "',Age='" & txtAge.Text & _
        "',Country='" & cmbCountry.Text & "'  WHERE PatientID='" & txtPatientID.Text & "'"
            .ExecuteNonQuery()
            MsgBox("Record Updated!", MsgBoxStyle.Information + MsgBoxStyle.OkOnly, "SUCCESS")
            Disable()
            Clear()
            SaveToolStripMenuItem.Enabled = False
            NewToolStripMenuItem.Enabled = True
            LoadPatientsRecord()
            getLastPatientID()
        End With
    End If
End Sub

请帮忙

Answer 1

您应该使用 SQL 参数。这些不仅会简化您的代码，而且会极不可能出现某些关于语法和数据类型的错误，并防止 SQL 注入(inject)攻击:

Dim sql = <sql> 
        UPDATE tblPatientsRecord SET [Names] = @p1,
                Licensenumber = @p2, 
                Address = @p3,
                Fullname = @p4,
                Birthday = @p5, 
                [Age] = @p6,
                Country = @p7
        WHERE PatientID = @p8
        </sql>.Value

Using conn = New OleDbConnection(myConnStr),
        cmd As New OleDbCommand(sql, conn)

    conn.Open()

    cmd.Parameters.Add("@p1", OleDbType.VarChar).Value = txtNames.Text
    cmd.Parameters.Add("@p2", OleDbType.VarChar).Value = txtLicensenumber.Text
    ' ...etc
    cmd.Parameters.Add("@p6", OleDbType.Integer).Value = intVar
    cmd.Parameters.Add("@p7", OleDbType.VarChar).Value = strVar

    'the last one is the WHERE
    cmd.Parameters.Add("@p8", OleDbType.VarChar).Value = Convert.ToInt32(lblPatientID.Text)

    cmd.ExecuteNonQuery()
    '... etc

End Using

还有一些其他常见问题需要注意。

1. DBConnection 对象旨在创建、使用和处置，而不是反复使用同一个对象。但是，您可以使用全局连接字符串，这样就不会到处都有相同的连接字符串。

2. 许多DBObject 应该被丢弃。 Using block 将关闭并处置连接和命令对象。一般来说，如果某些东西有 Dispose 方法，请将它们包装在 Using block 中。上面展示了如何将 2 个对象(OleDbConnection 和 OleDbCommand)“堆叠”到一个 Using 语句中，从而减少缩进。

   <

3. 使用Add方法而不是AddWithValue。这允许您指定每个参数的数据类型。如果没有它，数据库提供程序必须猜测哪个可能导致数据类型不匹配，甚至在某些情况下损坏数据库。

4. WHERE 子句只是另一个参数。通常人们会在 SQL 的第一部分使用参数，但不必要地连接 WHERE 子句。

5. 上面还使用 XML 文字来构造 SQL。这对于又长又复杂的 SQL 来说非常方便，因为您可以根据需要对其进行格式化和缩进。您也可以只使用多行来使其可读:

   Dim sql = "更新 tblPatientsRecord SET [名称] = @p1,"_ &“许可证号 = @p2,” _ &“地址=@p3，”

6. 如果您使用SQL reserved words或者表名或列名中存在空格，您必须使用 [方括号] 对名称进行转义，如下所示。最好不要在名称中使用任何一个。 User、Password Names 和 Values 是用作列或表名称的常见单词，会导致 SQL 语法错误。

7. 刻度不是通用的 SQL 字段分隔符，它们实际上指示传递的值是字符串/文本:& "Age ='"& txtAge.Text & “'”。如果数据库设置为将年龄存储为数字，则您的SQL会将其作为文本/字符串传递，这可能会导致数据类型不匹配。如果是日期字段，PatientID 和 Birthday 也是如此。

   连接 SQL 语句字符串的一个常见问题是结果中的刻度 (') 过多或过少。 SQL 参数不会发生这种情况。

SQL 参数的主要目的是防止名称为“O'Brian”或“O'Reilly”或 "Bobby';DROP TABLE tblPatientsRecord" 时出现错误。

这些原则适用于其他数据库提供商，例如 MySql、SQLite 和 SQLServer。然而，诸如确切的转义字符之类的细节会有所不同。

请注意，Access/OleDB 实际上并不使用这样的命名参数(@FirstName 甚至 @p2)，因此通常会请参阅“？”形式的参数。这意味着您必须按照这些列在 SQL 中显示的顺序添加参数值 (Add/AddWithValue)。

更多信息请参见:

• Using Statement
• Connection Pooling