Oracle:有没有办法获取最近的 SQL 语法错误？

Question

我们在应用程序日志中看到大量“ORA-00936:缺少表达式”错误。 Oracle 有没有办法确定哪些语句失败？

我尝试查询 v$sql，但这些语句没有插入到该 View 中，因为它们没有通过语法检查。

我们的 C# 应用程序使用 Linq 生成对 Oracle 数据库的查询。这使得从应用程序获取 sql 查询有点困难。我希望能够更轻松地从 Oracle 获取它。

Answer 1

您可以在 Oracle 中创建一个触发器来记录所有错误(或几乎所有错误 - NO_DATA_FOUND 不被视为错误)。在下面的示例中，架构中的任何错误都会记录在 TRACK_DETAIL 表中(一行中出现错误，下一行中出现失败的 SQL)。您可以使用序列号、日期/时间等使其变得更加复杂。

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

使用完毕后请记住删除(或禁用)触发器。