excel - 将动态范围和静态范围从Excel导入到不是从单元格A1开始的MS-Access

Question

如何链接Excel电子表格中的数据范围，以便该范围中的数据在Access中显示为可用表？

链接到具有以单元格A1开头的数据的Excel工作表很容易，但是在Excel电子表格中数据在工作表的其他地方开始的地方，我不确定如何获取Access来对其进行精确定位，尤其是在非A1的情况下。范围是动态的。

通过导入/链接向导 Access 时， Access 似乎没有选择命名/动态范围。

真实场景:

我有一个Excel电子表格文件，我们将其称为“ ExcelFile1.xls ”，该文件是从外部提供给我的(因此我无法真正更改其格式)。

工作表/标签中的1个，我们称之为“动态”，具有我要在Access中用作表的数据范围，但其列标题从第14行开始，一直到EL列。我想Access要做的是将这个数据范围作为一个表。此外，“ ExcelFile1.xls ”也将定期更新，即“ExcelFile.xls”文件的新版本将可用，但是在第14行的列标题下方有更多数据，因此，理想情况下，我想访问Access每当我覆盖以前版本的“ ExcelFile1.xls ”时，便会在此范围内获取新数据。

我还有另一个Excel电子表格文件，我们称它为“ ExcelFile2.xls ”，再次从外部提供给我。

它有一个工作表/标签，我们称它为“静态”，同样具有我要在Access中作为表使用的数据范围，并且再次，将有“ ExcelFile2.xls ”的较新版本，它将覆盖以前的版本。理想情况下，我希望Access能够继续发展。该范围是A14:O19，并且将始终是该范围(即静态范围)。

因此，总而言之:我想将Access链接到来自2个各自的Excel文件的2个数据范围，以生成Access中可用的2个单独的表。源数据范围中的一个将是动态的，而另一个将是静态的。我希望Access可以通过使用完全相同的文件名和路径的新版本简单覆盖源Excel文件来获取新数据。

Answer 1

好的，从关于此问题的有用指针以及我在其他地方提出的其他建议中，我认为对于想要从Excel电子表格中提取数据作为动态范围或静态范围的任何人，我都有一个非常简单的解决方案Excel中的数据不在单元格A1中启动。

这两个示例都使用按钮来初始化代码。显然，您不必这样做，但是如果您这样做，则需要创建一个表单和按钮，然后在该按钮上运行代码生成器，并用下面所需的任何解决方案替换该代码。

动态范围:

请注意，此动态范围示例假设您在Excel中的单元格范围始终始于相同的最左上角位置，并且列数始终相同-即唯一动态的是您的细胞范围。

您需要根据自己的设置换出引用:

C:\Users\Matt\Desktop\ExcelFile1.xls替换为Excel文件

的完整路径

Dynamic替换为Excel文件

中包含的工作表名称

A14:A2000替换为要测试的范围，以查看有多少个非空单元格。此范围应:从列标题所在的数据行开始；覆盖您要导入的数据中的一列，该列永远不会有空单元格条目；覆盖的范围足够大，它将始终超过Excel电子表格中包含实际数据的行数。

ExcelDynamicRangeData用您要在Access中调用的表替换，该表将包含从Excel范围提取的数据。

Dynamic!A14:EL替换为工作表名称，Excel范围的最顶部/最左侧的单元格引用和最右侧的列字母。不要包括最底/最​​右的行号，因为这是动态的，因此将其分配给numberofrows并将其串联到此范围的末尾。

numberofrows = 13 ...用上面的列标题开始处的多行替换13。例如。如果您的列标题从第4行开始，则此数字必须为3。

Command0替换为用于启动所有此代码的按钮的名称。

Sub ImportDataFromRange()

' Assign the Excel Object
Dim excelapp As Object
Set excelapp = CreateObject("excel.application")

' Assign the workbook
Dim wb As Object
Set wb = excelapp.Workbooks.Open("C:\Users\Matt\Desktop\ExcelFile1.xls")

' Assign the result of your CountA function used in the next line
Dim numberofrows As Integer

' Get the bottom-most row number needed to complete our dynamic range address
numberofrows = 13 + excelapp.Application.CountA(wb.worksheets("Dynamic").Range("A14:A2000"))

' Delete any previous access table, otherwise the next line will add an additional table each time it is run
DoCmd.DeleteObject acTable, "ExcelDynamicRangeData"

' Import data from Excel using a range that now knows where bottom row number is
DoCmd.TransferSpreadsheet acLink, acSpreadsheetTypeExcel9, "ExcelDynamicRangeData", "C:\Users\Matt\Desktop\ExcelFile1.xls", True, "Dynamic!A14:EL" & numberofrows

' Close and clean
wb.Close
Set wb = Nothing
excelapp.Quit
Set excelapp = Nothing

End Sub    

Private Sub Command0_Click()

ImportDataFromRange

End Sub

静态范围:

这非常简单，因为无需打开Excel工作簿即可在数据上应用CountA函数。

您需要根据自己的设置换出引用:

C:\Users\Matt\Desktop\ExcelFile2.xls替换为Excel文件

的完整路径

ExcelStaticRangeData用您要在Access中调用的表替换，该表将包含从Excel范围提取的数据。

Static!A14:EL20替换为工作表名称以及要导入的Excel中单元格的完整范围地址。由于此方法描述了如何从Excel中获取静态数据范围以 Access 要导入的Excel中的数据，因此永远不要超出此范围。

Command0替换为用于启动所有此代码的按钮的名称。

Sub ImportDataFromRange()

' Delete any previous access table, otherwise the next line will add an additional table
DoCmd.DeleteObject acTable, "ExcelStaticRangeData"

' Import data from Excel using a static range
DoCmd.TransferSpreadsheet acLink, acSpreadsheetTypeExcel9, "ExcelStaticRangeData", "C:\Users\Matt\Desktop\ExcelFile2.xls", True, "Static!A14:EL20"

End Sub    

Private Sub Command0_Click()

ImportDataFromRange

End Sub

NB :

两种方法中的acSpreadsheetTypeExcel9位均指您要导入的Excel文件的版本。在我的示例中，我将导入Excel 2000格式；您可能正在导入其他版本的Excel，因此请引用this以查看您需要在代码中引用的版本； .xlsx文件未列出，但是它将是acSpreadsheetTypeExcel12Xml。

我的示例将数据作为到源数据的事件链接引入Access中。如果您有很多数据，则可能会发现将数据实际导入和存储到Access中更好，因为链接可能会导致一些性能问题。在这种情况下，将acLink换为acImport。

如果尚未在Access中手动创建空白表(代码中引用了相同的表名)，则需要这样做或在第一次运行代码时将DoCmd.DeleteObject acTable, "yourAccessTable"注释掉，然后恢复该状态之后。

这样做可能还有更多的事情可以做-即，如果您的数据源具有不同的列数，则对CountA函数进行调整以考虑动态列数。

再次感谢@ david-zemens，@ gord-thompson以及其他StackoverFlow用户帮助我实现了这一点-这对我和希望对其他人将非常有用。