java - 如何修复与语义谓词一起使用的左递归中的错误？

Question

我想用 boolean 值解析两种类型的表达式:
- 第一个是带有 boolean 值的初始化表达式，例如:init : false
- 最后一个是带有 boolean 值的派生表达式，例如:derive : !express or (express and (amount >= 100))

我的想法是将语义谓词放入一组规则中， 目标是当我解析以“init”一词开头的 boolean 表达式时，它必须只转到一个提议的替代规则，即boolliteral，即boolExpression中的最后一个替代规则强>。如果它是一个以“derive”一词开头的表达式，那么它可以访问 boolExpression 的所有替代项。

我知道我可以创建两种类型的 boolExpression，而无需像 boolExpressionInit 和 boolExpressionDerive 这样的语义谓词...但是我想尝试一下我的想法，如果它可以仅与一种带有语义谓词的 boolExpression 一起使用。

这是我的语法

grammar TestExpression;

@header
{
package testexpressionparser;
}

@parser::members {
                    int vConstraintType;
                 }

/* SYNTAX RULES */
textInput       : initDefinition 
                | derDefinition ;

initDefinition  : t=INIT {vConstraintType = $t.type;} ':' boolExpression ;

derDefinition   : t=DERIVE {vConstraintType = $t.type;} ':' boolExpression ;

boolExpression  : {vConstraintType != INIT || vConstraintType == DERIVE}? boolExpression (boolOp|relOp) boolExpression 
                | {vConstraintType != INIT || vConstraintType == DERIVE}? NOT boolExpression
                | {vConstraintType != INIT || vConstraintType == DERIVE}? '(' boolExpression ')' 
                | {vConstraintType != INIT || vConstraintType == DERIVE}? attributeName
                | {vConstraintType != INIT || vConstraintType == DERIVE}? numliteral
                | {vConstraintType == INIT || vConstraintType == DERIVE}? boolliteral
                ;

boolOp          : OR | AND ;
relOp           : EQ | NEQ | GT | LT | GEQT | LEQT ;
attributeName   : WORD;
numliteral      : intliteral | decliteral;
intliteral      : INT ;
decliteral      : DEC ;
boolliteral     : BOOLEAN;


/* LEXICAL RULES */
INIT            : 'init';
DERIVE          : 'derive';
BOOLEAN         : 'true' | 'false' ;
BRACKETSTART    : '(' ;
BRACKETSTOP     : ')' ;
BRACESTART      : '{' ;
BRACESTOP       : '}' ;
EQ              : '=' ;
NEQ             : '!=' ;
NOT             : '!' ;
GT              : '>' ;
LT              : '<' ;
GEQT            : '>=' ;
LEQT            : '<=' ;
OR              : 'or' ;
AND             : 'and' ;
DEC             : [0-9]* '.' [0-9]* ;
INT             : ZERO | POSITIF;
ZERO            : '0';
POSITIF         : [1-9] [0-9]* ;
WORD            : [a-zA-Z] [_0-9a-zA-Z]* ;
WS              : (SPACE | NEWLINE)+ -> skip ;
SPACE           : [ \t] ;                       /* Space or tab */
NEWLINE         : '\r'? '\n' ;                  /* Carriage return and new line */

我除了语法会成功运行之外，但我收到的是:“error(119): TestExpression.g4:::以下规则集是相互左递归的 [boolExpression]
1 个错误 构建失败”

Answer 1

显然，当谓词出现在左递归规则调用之前时，ANTLR4 对(直接)左递归的支持不起作用。因此，您可以通过在左递归替代方案中的第一个 boolExpression 之后移动谓词来修复错误。

也就是说，似乎谓词从一开始就不是真正必要的 - 至少在您向我们展示的示例中不是这样(或者据我所知，在您编辑之前的示例中)。由于约束类型为 INIT 的 boolExpression 显然只能匹配 boolLiteral，因此您只需更改 initDefinition 即可，如下所示:

initDefinition  : t=INIT ':' boolLiteral ;

然后 boolExpression 将始终具有约束类型 DERIVE 并且不再需要谓词。

通常，如果您希望根据是由 y 还是 z 调用，在非终端 x 中允许不同的替代方案，您应该简单地拥有 x 的多个版本，然后从 y 调用一个版本，从 z 调用另一个版本。这通常比在代码中乱扔操作和谓词要少很多麻烦。

类似地，拥有一个比应有的匹配更多的规则，然后在稍后阶段检测非法表达式，而不是尝试在语法级别拒绝它们，也是有意义的。具体来说，初学者经常尝试编写只允许类型正确的表达式的语法(拒绝诸如 1+true 之类的语法错误)，但效果永远不会很好。