regex - sed 用 C++ 注释替换(单行)C 注释

Question

如何使用 sed 将源文件中的所有 C 风格注释替换为 C++ 风格。

所有这些:

int main() {
  /* some comments */
  ...

至:

int main() {
  // some comments
  ...

所有注释都是单行，并且代码之间没有像这样的注释:

int f(int x /*x-coordinate*/ );

所以我尝试了这个:

 sed -i 's/ \/\* .*  \*\ / \/\/* /g' src.c

但它使文件保持不变。 This帖子类似，但我试图理解 sed 的表达式语法。自从 ”。”匹配任何字符，“* ”匹配零个或多个某种模式。我假设“.*”匹配任意数量的任意字符。

Answer 1

sed -i 's:\(.*\)/[*]\(.*\)[*]/:\1 // \2:' FILE

这将像这样转换每一行:

aaa  /* test */

像这样的一行:

aaa  // test

如果同一行有更多注释，您可以应用这个更复杂的解析器，它可以将行转换为:

aaa /* c1 */ bbb /* c2 */ ccc

进入

aaa  bbb ccc // c1 c2

<小时/>

sed -i ':r s:\(.*\)/[*]\(.*\)[*]/\(.*\):\1\3 //\2:;tr;s://\(.*\)//\(.*\)://\2\1:;tr' FILE

更复杂的情况是当您在一行字符串中添加注释时，例如 call("/*string*/") 中。这是一个脚本c-comments.sed，用于解决这个问题:

s:\(["][^"]*["]\):\n\1\n:g
s:/[*]:\n&:g
s:[*]/:&\n:g
:r
s:["]\([^\n]*\)\n\([^"]*\)":"\1\2":g
tr
:x
s:\(.*\)\n/[*]\([^\n]*\)[*]/\n\(.*\)$:\1\3 // \2:
s:\(.*\)\n\(.*\)//\(.*\)//\(.*\):\1\n\2 //\4\3:
tx
s:\n::g

将此脚本保存到文件 c-comments.sed 中，并按如下方式调用它:

sed -i -f c-comments.sed FILE