.net - 如何在 F# 中模拟鼠标点击和按键

Question

我正在编写一个程序，该程序应该移动鼠标并在我在代码中指定的位置自动按下。现在我已经成功地使用这一行移动光标: Cursor.Position <- System.Drawing.Point(x,y)

我还没有找到的是如何模拟鼠标点击或按键。我发现的唯一的事情是来自 MSDN 的 SendKeys 类 (http://msdn.microsoft.com/en-us/library/system.windows.forms.sendkeys.aspx)。我尝试用此类模拟按键，但收到运行时错误消息。

我使用的线路是: SendKeys.Send("{ENTER}")

我收到的错误消息: “SendKeys 无法在此应用程序内运行，因为该应用程序不处理 Windows 消息。要么更改应用程序来处理消息，要么使用 SendKeys.SendWait 方法。”

所以我用SendWait方法替换它，但它似乎仍然没有发送按键。我该怎么做呢？我真正希望完成的程序能够做到的是将按键和鼠标点击发送到另一个已经在后台打开的程序。例如，在“画图”中自动绘制图像。

Answer 1

如果您想避免 Win32 native 互操作，Windows Input Simulator是一个看起来很有前途的托管包装器 SendInput 。但最新版本不支持鼠标模拟。然而，事件主干有一个支持鼠标模拟的补丁(参见this讨论)。该项目使用 VS2010 C#，您可以从 subversion 存储库导出并自行构建 here .

如果您对 Win32 native 互操作感兴趣，我整理了如何通过 F# 使用 SendInput API 的演示。该应用程序模拟右键单击。

open System
open System.Runtime.InteropServices

type MOUSEINPUT = struct
    val dx:int
    val dy:int
    val mouseData:int
    val dwFlags:int
    val time:int
    val dwExtraInfo:int
    new(_dx, _dy, _mouseData, _dwFlags, _time, _dwExtraInfo) = {dx=_dx; dy=_dy; mouseData=_mouseData; dwFlags=_dwFlags; time=_time; dwExtraInfo=_dwExtraInfo}
end

type INPUT = struct
    //need to escape traditional INPUT identifier here since "type" is a reserved word
    //though could use any other identifier name if so desired
    val ``type``:int //0 is mouse
    val mi:MOUSEINPUT
    new(_type, _mi) = {``type``=_type; mi=_mi}
end

let MOUSEEVENTF_RIGHTDOWN = 0x0008
let MOUSEEVENTF_RIGHTUP = 0x0010

[<DllImport("user32.dll", SetLastError=true)>]
extern uint32 SendInput(uint32 nInputs, INPUT* pInputs, int cbSize)

let mutable inputRightDown = INPUT(0, MOUSEINPUT(0, 0, 0, MOUSEEVENTF_RIGHTDOWN, 0, 0))
let mutable inputRightUp = INPUT(0, MOUSEINPUT(0, 0, 0, MOUSEEVENTF_RIGHTUP, 0, 0))

SendInput(uint32 1, &&inputRightDown, Marshal.SizeOf(inputRightDown))
SendInput(uint32 1, &&inputRightUp, Marshal.SizeOf(inputRightUp))

在第二次阅读您的问题时，我发现您最终希望将模拟的鼠标和键盘事件发送到在后台运行的应用程序，在这种情况下 SendMessage/PostMessage可能是更合适的API。这仍然需要 native 互操作，希望我使用 SendInput 的示例会有所帮助。 Here是一个相关问题。