我正在尝试了解操作系统的工作原理。这是一个我很难解决的简单任务:编写一个简单的引导加载程序，提示用户输入他的名字并打印一条欢迎消息，例如“你好，>>name<<” - 之后，它什么也不做。
我正在运行minix 3与 qemu ，如果这有任何相关性的话。我只是编译了一个asm文件和 dd它的前 512 个字节为 /dev/c0d0 (minix的虚拟硬盘)。
我可以打印消息并打印用户正在输入的内容。然而，我后来没能打印出用户名。
这是我的汇编代码:
[bits 16]
[org 0x7c00]
mov si, HelloString
call print_string
mov di, name
call read_name
mov si, name
call print_string
read_name:
read_char:
mov ah, 0h ; read character from keyboard
mov [di], ah ; save it in the buffer
inc di ; next char
int 0x16 ; store it in AL
cmp ah, 0x0d ; check for enter
je stop_reading
mov ah, 0eh ; display character in AL
int 0x10 ; echo it
jmp read_char ; an so on
stop_reading:
mov si, EoL
call print_string
ret
print_char:
mov ah, 0x0e ; one char
mov bh, 0x00 ; page number
mov bl, 0x07 ; font color
int 0x10
ret
print_string:
next_char:
mov al, [si]
inc si
or al, al
jz exit_function
call print_char
jmp next_char
exit_function:
ret
;data
HelloString db 'Enter your name', 0xd, 0xa, 0
name times 20 db 0
EoL db 0xd, 0xa, 0
times 510 - ($ - $$) db 0;
dw 0xaa55
我做错了什么？
最佳答案
您的代码存在许多问题。罗斯和我在评论中指出了一些内容。你应该阅读我的General Bootloader Tips 。虽然与您的实际问题无关，但您应该将 DS (和 ES 如果您最终需要它)设置为 0，因为您使用原点 0x7c00 ( org 0x7c00 ) 。您还应该将堆栈设置在您知道代码不会被破坏的地方。我之前将此代码添加到顶部:
mov si, HelloString
call print_string
将其更改为:
xor ax, ax ; AX=0
mov ds, ax
mov es, ax
mov ss, ax ; SS=ES=DS=0
mov sp, 0x7c00 ; Place stack before the bootloader. Grows down from 0x0000:0x7c00
mov si, HelloString
call print_string
代码运行完毕后，您应该将 CPU 置于无限循环中，这样它就不会继续执行主代码下的函数。所以在标签 read_name: 之前放置一个无限循环。像这样的事情很典型:
cli ; Turn off interrupts
endloop:
hlt ; Halt processor until next interrupt encountered
jmp endloop ; Jump back just in case we get an MNI (non-maskable interrupt)
您的 read_char 中有一些错误功能。 BIOS 中断信息的最佳位置之一是 Ralph Brown's Interrupt List 。 Int 0x16/AH=0记录为:
AH = 00h Return: AH = BIOS scan code AL = ASCII character
您应该使用 AL 中的 ASCII 字符存储到字符串缓冲区中。您还应该将 AL 与 0x0d 进行比较，而不是 AH(这是键盘扫描代码，而不是 ASCII 字符)。在使用 int 0x16 读取字符之前，您还将数据存储到字符串缓冲区中。 。之后您需要将它们放入缓冲区中。当您到达stop_reading:时您需要在缓冲区末尾放置一个 NUL (0x00) 字符。
您的代码 read_name可能看起来像:
read_name:
read_char:
mov ah, 0h ; read character from keyboard
int 0x16 ; store it in AL
cmp al, 0x0d ; check for enter
je stop_reading
mov [di], al ; save it in the buffer
inc di ; next char
mov ah, 0eh ; display character in AL
int 0x10 ; echo it
jmp read_char ; an so on
stop_reading:
mov byte [di], 0x00 ; NUL terminate buffer
mov si, EoL
call print_string
ret
修改后的引导加载程序可能如下所示:
[bits 16]
[org 0x7c00]
xor ax, ax ; AX=0
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0x7c00 ; Place stack before the bootloader. Grows down from 0x0000:0x7c00
mov si, HelloString
call print_string
mov di, name
call read_name
mov si, name
call print_string
cli ; Turn off interrupts
endloop:
hlt ; Halt processor until next interrupt encountered
jmp endloop ; Jump back just in case we get an MNI (non-maskable interrupt)
read_name:
read_char:
mov ah, 0h ; read character from keyboard
int 0x16 ; store it in AL
cmp al, 0x0d ; check for enter
je stop_reading
mov [di], al ; save it in the buffer
inc di ; next char
mov ah, 0eh ; display character in AL
int 0x10 ; echo it
jmp read_char ; an so on
stop_reading:
mov byte [di], 0 ; NUL terminate buffer
mov si, EoL
call print_string
ret
print_char:
mov ah, 0x0e ; one char
mov bh, 0x00 ; page number
mov bl, 0x07 ; font color
int 0x10
ret
print_string:
next_char:
mov al, [si]
inc si
or al, al
jz exit_function
call print_char
jmp next_char
exit_function:
ret
;data
HelloString db 'Enter your name', 0xd, 0xa, 0
name times 20 db 0
EoL db 0xd, 0xa, 0
times 510 - ($ - $$) db 0;
dw 0xaa55
我强烈建议使用BOCHS调试引导加载程序。它有一个内置的调试器，可以理解实模式和实模式寻址，并且比QEMU
更适合调试引导加载程序关于assembly - 编写一个简单的引导加载程序来读取用户名，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/43265248/