java - 在 Clojure 中捕获系统/输出

Question

我正在使用一个将文本输出到控制台的 Java 包，我需要在字符串中捕获该文本，但我不确定如何执行此操作。从 Clojure 文档看来，我所要做的就是将 java 调用包装在 with-out-str 中，但这对我来说不起作用。

最小代码示例:如果我尝试

(with-out-str 
 (.println (System/out) "foo"))

我希望得到一个值为“foo”的字符串，但它仍然输出到控制台。我做错了什么？

Answer 1

Java 的 System.out.println(...) 是对 PrintStream 实例的 println 方法的调用。您需要将 System.out 流替换为您自己的实例并捕获其内容:

(import [java.io ByteArrayOutputStream PrintStream])

(def out-buffer (java.io.ByteArrayOutputStream.))

(System/setOut (java.io.PrintStream. out-buffer true "UTF-8"))

(defn out-str []
  (.toString out-buffer "UTF-8"))

但在 REPL 中要小心，因为它使用 System.out 来打印结果，因此当您全局替换它时，它会破坏您的 REPL 实例。

您甚至可以编写一个宏来捕获 System.out 的内容，然后恢复原始的 PrintStream 实例:

(defmacro with-system-out-str [& body]
  `(let [out-buffer# (ByteArrayOutputStream.)
         original-out# System/out
         tmp-out# (PrintStream. out-buffer# true "UTF-8")]
     (try
       (System/setOut tmp-out#)
       ~@body
       (finally
         (System/setOut original-out#)))
     (.toString out-buffer# "UTF-8")))

(with-system-out-str
  (.println System/out "Hi"))
;; => "Hi\n"