sql - 如何使用 Perl 获取 SQL 表上的索引列表？

Question

如何使用 Perl 获取 sybase 数据库中表的索引列表？目标是将表中的所有索引“复制”到几乎相同的表。

$dbh->selectarray_ref('sp_helpindex $table') 是我能做的最好的事情吗？

Answer 1

DBI 中有一个 stats_info() 方法，但不幸的是，到目前为止我见过的唯一实现它的 DBD 是 DBD::ODBC 。因此，如果您使用 ODBC(更新:或 PostgreSQL!)，那么您很幸运。否则，sp_helpindex(或 sysindexes 表)对于 Sybase 来说就已经是最好的了。

这是我在 Sybase 中使用的内容(在我自己的 OO 模块中 - 它仅返回唯一索引，除非 all_indexes 参数为 true):

{
my $sql_t = <<EOT;
select
  sysindexes.name,
  index_col(object_name(sysindexes.id), sysindexes.indid, syscolumns.colid) col_name
from sysindexes, syscolumns
where sysindexes.id = syscolumns.id
  and syscolumns.colid <= sysindexes.keycnt
  and sysindexes.id = object_id(%s)
EOT

sub index_info {
  my ( $self, $table, $all_indexes ) = @_;

  my $dbh = $self->{DBH};
  my $sql = sprintf $sql_t, $dbh->quote($table);
  $sql .= "and sysindexes.status & 2 = 2\n" unless $all_indexes;
  my $sth = $dbh->prepare($sql);
  $sth->execute();
  my @col_names = @{$sth->{NAME_lc}};
  my %row; $sth->bind_columns(\@row{@col_names});
  my %ind;
  while ($sth->fetch()) {
    if ( $row{col_name} ) {
      push @{$ind{$row{name}}}, lc($row{col_name});
    }
  }
  return unless %ind;
  return \%ind;
}

}

或者，如果您的目标只是复制索引，也许您应该获得 dbschema.pl实用程序(使用 Sybase::DBlib)。它将为您生成“CREATE INDEX”语句。