Delphi FMX dcpcrypt 在 macOS 64 位上结果错误

Question

我使用的是Delphi 10.3.2 我正在尝试将 DCPCrypt 单元与 firemonkey 框架结合使用来加密字符串。 它在 Win32、Win64 和 macOS 32 目标上 100% 工作，结果始终相同。但当我针对 macOS 64 进行编译时，结果有所不同。

这是使用的代码:

function EncodeAES(code:ansistring; key:ansistring):string;
var
    s,u:ansistring;
  enc: TEncoding;
  k,iv, Data, Crypt: TBytes;
  Cipher: TDCP_rijndael;
begin
    u:='';
    enc:=TEncoding.ANSI;
    Data := enc.GetBytes(code); // VMpuXJGbUNOv
    k:=enc.GetBytes(key);   // kj3214ed)k32nre2
    iv:=enc.GetBytes(u);
    Cipher:=TDCP_rijndael.Create(nil);
    Cipher.Init(K[0], 128, @iv[0]);
    Crypt:=Copy(Data, 0, Length(Data));
    BytePadding(Crypt, Cipher.BlockSize, pmPKCS7);
    Cipher.EncryptECB(Crypt[0], Crypt[0]);
    Cipher.Free;
    s:=tencoding.ANSI.GetString(crypt);
    result:=StringToHex(s);
end;

这是 BytePadding 函数:

procedure BytePadding(var Data: TBytes; BlockSize: integer; PaddingMode: TPaddingMode);
var
    I, DataBlocks, DataLength, PaddingStart, PaddingCount: integer;
begin
    BlockSize := BlockSize div 8;
    if PaddingMode in [pmZeroPadding, pmRandomPadding] then
        if Length(Data) mod BlockSize = 0 then Exit;
    DataBlocks := (Length(Data) div BlockSize) + 1;
    DataLength := DataBlocks * BlockSize;
    PaddingCount := DataLength - Length(Data);
    if PaddingMode in [pmANSIX923, pmISO10126, pmPKCS7] then
        if PaddingCount > $FF then Exit;
    PaddingStart := Length(Data);
    SetLength(Data, DataLength);
    case PaddingMode of
        pmZeroPadding, pmANSIX923, pmISO7816: // fill with $00 bytes
            FillChar(Data[PaddingStart], PaddingCount, 0);
        pmPKCS7: // fill with PaddingCount bytes
            FillChar(Data[PaddingStart], PaddingCount, PaddingCount);
        pmRandomPadding, pmISO10126: // fill with random bytes
            for I := PaddingStart to DataLength-1 do Data[I] := Random($FF);
    end;
    case PaddingMode of
        pmANSIX923, pmISO10126:
            Data[DataLength-1] := PaddingCount; // set end-marker with number of bytes added
        pmISO7816:
            Data[PaddingStart] := $80; // set fixed end-markder $80
    end;
end;

我将该函数称为:

procedure TForm1.BtnClick(Sender: TObject);
var
    s:string;
begin
    s:=EncodeAES('VMpuXJGbUNOv','kj3214ed)k32nre2');
end;

Win32/Win64/macOS 32 的结果(正确): E32A9DE47CC60BDB70CA27885128D17A

macOS 64 的结果(错误): CF622155545E485AC3A083E8A0478493

我做错了什么？

Answer 1

加密对二进制数据进行操作，而不是文本数据。处理文本时，必须在加密之前将字符编码为字节，然后在解密后将字节解码为字符。这意味着加密前和解密后使用相同的字符编码。您正在尝试进行该编码，但没有考虑到 TEncoding.ANSI 不能跨操作系统平台移植，甚至不能跨使用相同操作系统平台的不同计算机移植。为了更好的可移植性，您需要使用一致的编码，例如TEncoding.UTF8。

此外，TEncoding 仅适用于 UnicodeString，因此使用 TEncoding.GetBytes() 和 TEncoding.GetString() 与 AnsiString 将使用 RTL 的 ANSI 定义(而不是您的)执行 ANSI 和 Unicode 之间的隐式转换，生成您可能不期望的字节如果您的字符串中包含任何非 ASCII 字符。

您的 EncodeAES() 函数最好使用 (Unicode)String 进行所有字符串处理，并且忘记 AnsiString 甚至存在。尽管像 Linux 这样的平台主要是 UTF-8 系统，但 Delphi 的默认 (Unicode)string 在所有平台上都使用 UTF-16。如果要对 ANSI 字符串进行编码，请使用 RawByteString 来避免任何隐式转换(如果调用代码想要使用 UTF8String、AnsiString(N) 等) . 按原样加密 8 位字符，根本不使用 TEncoding。仅对 UnicodeString 数据使用 TEncoding。

最后，您的 EncodeAES() 函数不应将加密字节解码为 UnicodeString 只是为了将其转换为十六进制字符串。您应该按原样对加密字节进行十六进制编码。

试试这个:

function EncodeAES(const Data: TBytes; const Key: string): string; overload;
const
  Hex: array[0..15] of Char = ('0','1','2','3','4','5','6','7','8','9','A','B','C','D','E','F');
var
  enc: TEncoding;
  iv, k, Crypt: TBytes;
  Cipher: TDCP_rijndael;
  B: Byte;
  I: Integer;
begin
  enc := TEncoding.UTF8;
  iv := enc.GetBytes('');
  k := enc.GetBytes(Key);

  Cipher := TDCP_rijndael.Create(nil);
  try
    Cipher.Init(k[0], 128, @iv[0]);
    Crypt := Copy(Data, 0, Length(Data));
    BytePadding(Crypt, Cipher.BlockSize, pmPKCS7);
    Cipher.EncryptECB(Crypt[0], Crypt[0]);
  finally
    Cipher.Free;
  end;

  SetLength(Result, Length(Crypt)*2);
  I := Low(Result);
  for B in Crypt do
  begin
    Result[ I ] := Hex[(B shr 4) and $F];
    Result[I+1] := Hex[B and $F];
    Inc(I, 2);
  end;
end;

function EncodeAES(const S, Key: string): string; overload;
begin
  Result := EncodeAES(TEncoding.UTF8.GetBytes(S), Key);
end;

function EncodeAES(const S: RawByteString; const Key: string): string; overload;
begin
  Result := EncodeAES(BytesOf(S), Key);
end;