delphi - 使用Delphi + Jedi，设备发送USB数据时丢失 "too fast"

Question

使用 Jedi 库中的 Delphi XE2 和 TJvHidDevice 类，我成功地与 USB 设备 (pic32mx7 code> board，我的代码在上面运行)。通常的“发送请求，等待单个响应”的方式是有效的。

问题在于命令会导致大量连续响应。如果设备尽可能快地发送这些响应 - 或者即使我在它们之间添加一个小的延迟(例如 5 毫秒) - 我会丢失数据包(报告？帧？)。 OnDeviceData 事件似乎并没有为所有这些事件触发。如果我在设备代码中添加更大的延迟，问题就会消失。

我使用 USBPcap 程序捕获 USB 数据并将其转储到一个文件中，一旦我在 WireShark 中打开该文件，该文件包含设备发送的所有数据(我发送 255 个数据包作为测试) ，每个数据包中全部为零和一个“1”将其位置移动 1 个位置)。因此，我认为设备和 Windows 都在完成自己的工作。

为了确保我的 Delphi 代码没有错误，我尝试了 Jedi 示例项目“DevReader”(这里是 main.pas code )，它将数据转储到屏幕上，并且也丢失了数据包。

我觉得网上应该有更多关于 Jedi USB 类的信息，但我找不到它。

我也许可以通过聚合/压缩设备的响应来避免此问题，但仍然想知道发生了什么。

编辑:

1. 从控制台应用程序尝试:数据包不再丢失。
2. 修改了 Jedi 演示应用，仅对收到的数据包进行计数并更新屏幕上的计数器标签(不强制重新绘制窗口)- 不会丢失数据包。
3. 在 OnData 事件中添加了 sleep(1) - 没有丢失数据包。
4. 在 OnData 事件中添加了 sleep(2) - 再次丢失数据包。

这看起来读取数据的 Jedi 线程不得因任何处理而延迟 - 难道不应该进行一些数据缓冲(通过 Windows？)来允许这种类型的处理延迟吗？从数据包丢失“模式”来看，似乎有缓冲，但这还不够，因为我可以接收例如30 个数据包，然后丢失 5 个，然后收到另外 20 个，依此类推。

我将修改代码以复制数据并尽快退出 OnData 事件，以便线程具有最短的“停机时间”，并且我将报告结果。

Answer 1

由于问题的原因似乎与 USB 读取线程被 Synchronise 阻塞的时间(即主线程执行的数据处理)有关，因此我在线程代码，(TJvHidDeviceReadThread 类，JvHidControllerClass.pas 单元)。使用此单元和包含的类的任何代码应该仍然可以工作，无需任何修改，没有任何公共(public)更改。

新行为:每次读取数据时，都会将其放入线程安全列表中。现在它使用 Queue 而不是 Synchronize，但前提是它尚未排队。 Queued 方法从线程安全列表中读取，直到它为空。它为列表中的每个缓冲报告触发一个事件(与旧代码中的事件相同)。一旦列表为空，“已排队”标志就会重置，下次读取将再次导致排队。

在到目前为止的测试中我没有遇到丢包的情况。

线程类已扩展:

  TJvHidDeviceReadThread = class(TJvCustomThread)
  private
    FErr: DWORD;

    // start of additions
    ReceivedReports : TThreadList;
    Queued: boolean;
    procedure PushReceivedReport(const bytes: array of byte; const NumBytesRead: cardinal);
    function PopReceivedReport(var ReportID: byte; var ReportBytes: TBytes): boolean;
    procedure FlushBuffer;
    // end of additions

    procedure DoData;
    procedure DoDataError;
    constructor CtlCreate(const Dev: TJvHidDevice);
  protected
    procedure Execute; override;
  public
    Device: TJvHidDevice;
    NumBytesRead: Cardinal;
    Report: array of Byte;
    constructor Create(CreateSuspended: Boolean);
    //added destructor:
    destructor Destroy; override;
  end;

在实现部分，修改了以下内容:

constructor TJvHidDeviceReadThread.CtlCreate(const Dev: TJvHidDevice);
begin
  inherited Create(False);
  // start of changes
  ReceivedReports := TThreadList.Create; 
  // end of changes
  Device := Dev;
  NumBytesRead := 0;
  SetLength(Report, Dev.Caps.InputReportByteLength);
end;

procedure TJvHidDeviceReadThread.Execute;
...
...
...
    //replaced: Synchronize(DoData); with:
    PushReceivedReport (Report, NumBytesRead);
...

并添加了以下内容:

type

TReport = class
  ID: byte;
  Bytes: TBytes;
end;

destructor TJvHidDeviceReadThread.Destroy;
var
  l: TList;
begin
  RemoveQueuedEvents (self);
  try
    l := ReceivedReports.LockList;
    while l.Count>0 do
      begin
        TReport(l[0]).Free;
        l.Delete(0);
      end;
  finally
    ReceivedReports.UnlockList;
    FreeAndNil (ReceivedReports);
  end;

  inherited;
end;

procedure TJvHidDeviceReadThread.FlushBuffer;
var
  ReportID: byte;
  ReportBytes: TBytes;
begin
  while PopReceivedReport (ReportID, ReportBytes) do
        Device.OnData(Device, ReportID, ReportBytes, length(ReportBytes));
end;

function TJvHidDeviceReadThread.PopReceivedReport(var ReportID: byte; var ReportBytes: TBytes): boolean;
var
  l: TList;
  rep: TReport;
begin
  l := ReceivedReports.LockList;
  rep := nil;
  try
    result := l.Count>0;
    if result
      then
        begin
          rep := l[0];
          l.Delete(0);
        end
      else Queued := false;
  finally
    ReceivedReports.UnlockList;
  end;

  if result then
    begin
      ReportID := rep.ID;
      SetLength(ReportBytes, length(rep.Bytes));
      System.move (rep.Bytes[0], ReportBytes[0], length(rep.Bytes));
      rep.Free;
    end;
end;

procedure TJvHidDeviceReadThread.PushReceivedReport(const bytes: array of byte; const NumBytesRead: cardinal);
var
  rep: TReport;
begin
  rep := TReport.Create;
  setlength (rep.Bytes, NumBytesRead-1);
  rep.ID := Bytes[0];
  System.move (Bytes[1], rep.Bytes[0], NumBytesRead-1);

  // explicitely lock the list just to provide a locking mechanism for the Queue flag as well
  ReceivedReports.LockList;
  try
    if not Queued then
      begin
        Queued := true;
        Queue (FlushBuffer);
      end;
    ReceivedReports.Add(rep);
  finally
    ReceivedReports.UnlockList;
  end;
end;