我主要是一名 PHP 开发人员，但我有一些我们以前的开发人员制作的旧 ASP，它坏了，我不知道如何修复它。我们有一个程序，它将一些变量发送到监听器页面，该监听器页面将该数据与 msSQL 数据库中的注册代码进行比较，然后让程序知道注册代码是否有效。
我在哪里遇到以下错误
.Parameters.Append .CreateParameter("@code", adVarChar, 1, 50, x)
是第 134 行:
ADODB.Parameters error '800a0e7c'
Parameter object is improperly defined. Inconsistent or incomplete information was provided.
/checkregistrationpro.asp, line 134
我已经在包含文件中指定了任何未包含在代码中的命名常量，因此与此无关。
我的连接字符串(我已经验证这些设置是否正确):
set conn = Server.CreateObject("ADODB.Connection")
set cmd = Server.CreateObject("ADODB.Command")
sConnString = "Provider=sqloledb; Data Source=MYDATASOURCE; Initial Catalog=MYCATALOG; User ID=MYUSERID; Password='MYPASSWORD';"
conn.Open sConnString
我的代码:
...
Function BlockInjectCode(StrVal)
BlockInjectCode = Replace(StrVal,"--","")
BlockInjectCode = Replace(BlockInjectCode,"'","")
BlockInjectCode = Replace(BlockInjectCode,"""","")
if instr(lcase(BlockInjectCode),"<") > 0 then
BlockInjectCode = ""
end if
End Function
x = BlockInjectCode(Request.QueryString("rid"))
uid = BlockInjectCode(Request.QueryString("uid"))
chkcode = BlockInjectCode(Request.QueryString("Code"))
CheckPro = BlockInjectCode(Request.QueryString("pro"))
CheckProProd = BlockInjectCode(Request.QueryString("prod"))
CheckProMac = BlockInjectCode(Request.QueryString("mac"))
MacAdd = CheckProMac
CodeValid = False
if x <> "" and uid <> "" then
'-- Get information about this registration code.
sqlStr = "select * from MYTABLE where Code = ? and IsValid = 1"
set cmdCodes = Server.CreateObject("ADODB.Command")
Set cmdCodes.ActiveConnection = Conn
cmdCodes.CommandText = sqlStr
with cmdCodes
.Parameters.Append .CreateParameter("@code", adVarChar, 1, 50, x)
end With
Set rsCodes = cmdCodes.execute
...
最佳答案
常见的情况是您没有定义 adVarChar，因此 CreateParameter() 方法“定义不正确”。
这只是 ADODB 库中众多命名常量之一的示例。处理这个问题的一种困惑的方法是自己定义值，例如:
Const adVarChar = 200
这种方法的问题是您必须定义所有命名常量，这可能会让人头疼。另一种方法是跳过整个命名常量并仅使用整数值，因此调用将是；
.Parameters.Append .CreateParameter("@code", 200, 1, 50, x)
然而，这并不容易阅读，尽管看起来您已经使用 1 的 ParameterDirectionEnum 值(即命名常量 adParamInput)执行此操作 在 ADODB 库中。无论如何，我不会推荐这种方法。
稍微好一点的方法是使用 #include 指令，以便它在调用页面中包含您可能需要的所有命名常量定义，这就是大多数人的做法。 Microsoft 为此目的通过 IIS (或者可能是我不确定的 MDAC 库安装) 提供了一个预定义文件，称为 adovbs.inc或adovbs.asp，通过包含此文件，您的页面将可以访问其中的所有命名常量定义。
所有这一切的原因是 VBScript 不支持类型库，因此在 客户端 场景中，您自己定义它们或从 adovbs.inc 文件复制并粘贴你唯一的选择。然而，在服务器场景中，我们仍然拥有 IIS 的强大功能，它可以让我们做一些时髦的事情。
如果类型库只需添加一次并且您不必担心它，那不是很好吗？不需要定义烦人的常量？让我们面对现实吧，它们已经存在于类型库中，那么为什么我们不能从那里获取它们呢？事实证明，我们可以感谢 METADATA 指令。
这是一个例子；
<!--
METADATA
TYPE="TypeLib"
NAME="Microsoft ActiveX Data Objects 2.5 Library"
UUID="{00000205-0000-0010-8000-00AA006D2EA4}"
VERSION="2.5"
-->
这种方法的优点在于您可以用于任何类型库(最好暴露给 COM)，并且您可以在一个页面中定义，或者将其添加到 global.asa 已在整个 Web 应用程序中定义。
通过这种方法，您可以安全地使用类似的代码；
.Parameters.Append .CreateParameter("@code", adVarChar, adParamInput, 50, x)
有用的链接
关于vbscript - ADODB.Parameters 错误 '800a0e7c' 参数对象定义不正确。提供的信息不一致或不完整，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/35511870/