XSLT 1.0 贪婪背包分组方法？

Question

我有一个 XML 数据集(从 SharePoint 2007 提供给 DVWP)，其结构如下:

<Rows>
  <Row ID="1" Spanoffset="0" Span="55" Spantail="55"/>
  <Row ID="2" Spanoffset="30" Span="31" Spantail="61"/>
  <Row ID="3" Spanoffset="61" Span="20" Spantail="81"/>
  <Row ID="4" Spanoffset="82" Span="30" Spantail="112"/>
</Rows>

假设每一行代表一个从@Spanoffset开始的条形。是 @Span宽，@Spantail在那里，所以如果我需要它，我就不必计算它。我正在尝试有效地将行打包在一起，以便将不会重叠的行分组在一起。数据集按 @Spanoffset 预排序。这本质上是一个背包问题，因为每一行可以适合多个可能的组。我想做的是一个简单的贪婪解决方案，并且知道如何用 c# 或 java 对其进行编码，但由于我无法将节点标记为已访问(我可以，但当我返回递归树时我会丢失它)而且我在访问节点时似乎无法删除它们，我不知道如何解决这个问题。

例如，上面的数据看起来像这样:

<div style="clear:both">
  <div style="width: 110px; margin-left: 0px; float:left;">1</div>
  <div style="width: 40px; margin-left: 12px; float:left;">3</div>
  <div style="width: 60px; margin-left: 2px; float:left;">4</div>
</div>
<div style="clear:both">
  <div style="width: 62px; margin-left: 60px; float:left;">2</div>
</div>

我一直没有费心去尝试让浮标正常工作，因为我还没有能够获得 Row每个节点仅以正确的顺序出现一次。一旦我把它们拿到那里，我就相当确定我可以解决格式问题。

迄今为止我想出的最好的 XSLT 是:

<xsl:template match="row">
  <xsl:variable name="tail" select="@Spantail"/>
  <div style="width:{2*@Span}px;
    left:{2*(@Spanoffset)}px;">
    <xsl:value-of select="@ID"/>
  </div>                        
  <xsl:apply-templates select="(following-sibling::row)[@Spanoffset>=$tail][1]"/>
</xsl:template>

生成

<div style="width: 110px;left: 0px">1</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 62px; left: 60px">2</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 60px; left: 164px">4</div>

所以我的问题有 2 个(我认为)，我认为它们是相互交织的。 1)如何修复/重构我的模板以仅发出每行一次。 和 2)如何将分组包装在容器中<div>元素。

我已经为此苦苦思索了两天了，有人能帮忙吗？

编辑: 好吧，经过一番 sleep 后，我通过向模板添加 bool 参数并使用一些 CDATA 来获得包装容器。要发出的标签 <div>真实时标记。 bool 值默认为 true，当我调用嵌套的 apply-templates 时，我将其设置为 false，从而将组包装在容器中。我仍然看不到标记<Row>的方法已访问过。

Answer 1

我认为仅使用核心 XSLT 非常棘手，但使用 node-set() 会更容易，一个XSLT扩展函数:

<xsl:template name="add-row">
    <xsl:param name="row"/>
    <xsl:param name="prev-group" />
    <xsl:if test="$row and not($row/@ID = $prev-group/Row/@ID)">
        <xsl:copy-of select="$row" />
        <xsl:call-template name="add-row">
            <xsl:with-param name="row" select="$row/following-sibling::Row[@Spanoffset &gt; $row/@Spantail][1]" />
            <xsl:with-param name="prev-group" select="$prev-group" />
        </xsl:call-template>
    </xsl:if>   
</xsl:template>

<xsl:template name="add-group">
    <xsl:param name="first-row" />
    <xsl:param name="prev-group" select="exsl:node-set(/)" />
    <xsl:if test="$first-row">
        <xsl:variable name="group">
            <xsl:call-template name="add-row">
                <xsl:with-param name="row" select="$first-row" />
                <xsl:with-param name="prev-group" select="$prev-group" />
            </xsl:call-template>
        </xsl:variable>
        <div clear="both">
            <xsl:for-each select="exsl:node-set($group)/Row">
                <div style="width: {2*@Span}px; left: {2*@Spanoffset}px"><xsl:value-of select="@ID"/></div>                             
            </xsl:for-each>
        </div>
        <xsl:call-template name="add-group">
            <xsl:with-param name="first-row" select="$first-row/following-sibling::Row[@Spanoffset &lt; preceding-sibling::Row/@Spantail][1]" />
            <xsl:with-param name="prev-group" select="exsl:node-set($group)" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template match="Rows">
    <xsl:call-template name="add-group">
        <xsl:with-param name="first-row" select="Row[1]" />
    </xsl:call-template>
</xsl:template>

不要忘记在样式表标记中声明扩展前缀和命名空间:

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  extension-element-prefixes="exsl"
  xmlns:exsl="http://exslt.org/common">

http://exslt.org/common是 Java XSLT 处理器的有效命名空间，例如 Xalan 或 Saxon；如果您使用 MSXML，请改用 urn:schemas-microsoft-com:xslt。