c++ - 在 CMake 中使用编译器前缀命令(distcc、ccache)

Question

有些实用程序通过添加命令作为前缀来使用现有编译器(因此，您可以调用 cc -c file.c，而不是调用 distcc cc -c file.c)。

使用 CMake 时可以更改编译器命令，但是我在尝试使用 distcc 时遇到了问题，尽管这可能适用于编译器的任何命令前缀(ccache 也是)。

• CMake 期望编译器是绝对路径，
  所以设置CMAKE_C_COMPILER至/usr/bin/distcc /usr/bin/cc , 报错:
  

  /usr/bin/distcc /usr/bin/cc is not a full path to an existing compiler tool.

• 将编译器设置为 /usr/bin/distcc和
  CMAKE_C_COMPILER_ARG1或 CMAKE_C_FLAGS从 /usr/bin/cc 开始在某些情况下有效，但因 CHECK_C_SOURCE_COMPILES 而失败
  (检查是否有某种方法可以支持这一点，即使前缀 CMAKE_REQUIRED_FLAGS 也不起作用)。

---

我发现这样做的唯一方法是将命令包装在 shell 脚本中。

#!/bin/sh
exec /usr/bin/distcc /usr/bin/cc "$@"

虽然这可行，但如果能够在 CMake 中使用编译器帮助程序，而不必通过 shell 脚本(当构建系统可以只使用命令前缀时会产生一些小开销)，那就太好了。

---

所以我的问题是:

CMake 是否可以直接使用编译器前缀命令(如 distcc)？无需 shell 脚本包装器？

Answer 1

自从 CMake 3.4.0有一个CMAKE_<LANG>_COMPILER_LAUNCHER变量和对应的目标属性<LANG>_COMPILER_LAUNCHER .因此，如果您的项目是纯 C 语言，您可以执行以下操作:

cmake -DCMAKE_C_COMPILER_LAUNCHER=ccache /path/to/source
CCACHE_PREFIX=distcc make -j`distcc -j`

如果您有 C++ 项目，请使用 -DCMAKE_CXX_COMPILER_LAUNCHER=ccache。

或者，让你的 CMakeLists.txt 智能并自动使用 ccache(如果可以找到):

#-----------------------------------------------------------------------------
# Enable ccache if not already enabled by symlink masquerading and if no other
# CMake compiler launchers are already defined
#-----------------------------------------------------------------------------
find_program(CCACHE_EXECUTABLE ccache)
mark_as_advanced(CCACHE_EXECUTABLE)
if(CCACHE_EXECUTABLE)
  foreach(LANG C CXX)
    if(NOT DEFINED CMAKE_${LANG}_COMPILER_LAUNCHER AND NOT CMAKE_${LANG}_COMPILER MATCHES ".*/ccache")
      message(STATUS "Enabling ccache for ${LANG}")
      set(CMAKE_${LANG}_COMPILER_LAUNCHER ${CCACHE_EXECUTABLE} CACHE STRING "")
    endif()
  endforeach()
endif()