用于 Jenkins 的 Android Studio : How to create build. gradle 文件？

Question

我是 gradle 的新手，正在尝试弄清楚如何在我们的 Jenkins 构建机器上设置它。我们的应用程序在 Android Studio 中完美构建，但它从未生成 build.gradle 文件，我相信我需要它才能在 Jenkins 上运行 gradle 构建。

感谢任何帮助!

Answer 1

我最终从头开始创建了这些构建文件。

这里有一些指南:

1. 如果您的项目包含多个模块，请在项目的根目录(与所有模块处于同一级别)创建一个 settings.gradle 文件。您的 settings.gradle 文件应如下所示:

   include 'ActionBarSherlock'
   include ':facebook-android-sdk-3.0.1:facebook'
   include 'google-play-services_lib'
   include ':SlidingMenu-master:library'
   include 'Tinder'
   include 'ViewPagerIndicator'
   include 'volley'
   include 'windowed-seek-bar'
   

2. 在每个模块中，创建一个 build.gradle 文件。对于库项目，您的 build.gradle 文件应如下所示:

   buildscript {
       repositories {
           mavenCentral()
       }
   
       dependencies {
           classpath 'com.android.tools.build:gradle:0.4.2'
       }
   }
   
   apply plugin: 'android-library'
   
   dependencies {
       compile 'com.android.support:support-v4:13.0.0'
   }
   
   android {
       buildToolsVersion "17.0"
       compileSdkVersion 17
   
       sourceSets {
           main {
               manifest.srcFile 'AndroidManifest.xml'
               java.srcDirs = ['src']
               resources.srcDirs = ['src']
               aidl.srcDirs = ['src']
               renderscript.srcDirs = ['src']
               res.srcDirs = ['res']
               assets.srcDirs = ['assets']
           }
   
           instrumentTest.setRoot('tests')
       }
   }
   

3. 对于您的主项目，您的 build.gradle 文件应如下所示:

   buildscript {
       repositories {
           mavenCentral()
       }
   
       dependencies {
           classpath 'com.android.tools.build:gradle:0.4.2'
       }
   }
   
   apply plugin: 'android'
   
   dependencies {
       compile project(':facebook-android-sdk-3.0.1:facebook')
       compile project(':google-play-services_lib')
       compile project(':SlidingMenu-master:library')
       compile project(':ViewPagerIndicator')
       compile project(':volley')
       compile project(':windowed-seek-bar')
       compile files('compile-libs/androidannotations-2.7.1.jar', 'libs/Flurry_3.2.1.jar', 'libs/google-play-services.jar', 'libs/gson-2.2.4.jar', 'libs/picasso-1.1.1.jar')
   }
   
   android {
       buildToolsVersion "17.0"
       compileSdkVersion 17
   
       sourceSets {
           main {
               manifest.srcFile 'AndroidManifest.xml'
               java.srcDirs = ['src']
               resources.srcDirs = ['src']
               aidl.srcDirs = ['src']
               renderscript.srcDirs = ['src']
               res.srcDirs = ['res']
               assets.srcDirs = ['assets']
           }
       }
   }