android - gradle中的多口味编译依赖

Question

有没有办法在 Android Studio (build.gradle) 中通过多种风格编译依赖项？

我有 2 个 flavorGroup，每组有 2 个变体。在 4 种可能的组合中，我希望仅当我既是最新版本又是免费版本时才能够依赖一个库。 latestCompile 或 freeCompile 有效，但 latestFreeCompile 无效。这是我的 build.gradle 的相关部分:

android {
    defaultConfig {
        minSdkVersion 7
        targetSdkVersion 19
        versionCode 15
        versionName "1.9." + versionCode
    }

    flavorGroups 'sdk', 'cost'

    productFlavors {
        latest {
            flavorGroup 'sdk'
            minSdkVersion 8
        }
        sdk7 {
            flavorGroup 'sdk'
            minSdkVersion 7
            versionName android.defaultConfig.versionName + ".sdk7"
        }
        free {
            flavorGroup 'cost'
        }
        pro {
            flavorGroup 'cost'
        }
    }
}
dependencies {
    // this works:
    freeCompile files('libs/StartAppInApp-2.2.1.jar')

    // and I would like something like this:
    latestFreeCompile 'com.google.android.gms:play-services:4.1.32' // minSdkVersion:8
}

如果我会使用:

latestCompile 'com.google.android.gms:play-services:4.1.32'

然后它也会包含在 latestPro 中(不需要) 如果我使用:

freeCompile 'com.google.android.gms:play-services:4.1.32'

然后它也会包含在 sdk7Free 中(尽管它需要 SDK 8)

Answer 1

如官方Android Developers website上所述，如果您想为产品风格和构建类型的特定组合声明依赖项，您需要先声明该配置。

例如对于 free 风格和 debug 类型:

configurations {
    freeDebugImplementation {}
}

dependencies {
    freeDebugImplementation 'com.google.firebase:firebase-ads:9.8.0'
}

---

高级:多个 flavor 维度

请注意，如果您的应用具有多个 flavor 维度，您必须创建与完整构建变体(所有 flavor ，然后是构建类型)相对应的配置，如下所示:

flavorDimensions "money", "image" 
productFlavors {
    free { dimension "money" }
    paid { dimension "money" }

    picasso { dimension "image" }
    glide { dimension "image" }
}

configurations {
    freePicassoDebugImplementation {}
    freeGlideDebugImplementation {}
}

dependencies {
    freePicassoDebugImplementation 'com.google.firebase:firebase-ads:9.8.0'
    freeGlideDebugImplementation 'com.google.firebase:firebase-ads:9.8.0'
}