c++ - 如何让项目将其构建输出与 Scons 放在同一目录中？

背景

我正在通过设置一个包含两个子项目的基本 C++ 示例项目来尝试 Scons:

Prj1 是一个依赖于 Prj2 的 EXE
Prj2 是一个导出部分函数的 DLL

我遇到的问题是该库将其 .obj、.pdb、.lib、.dll 等文件构建在与其 SConscript 文件相同的目录中，而 EXE 将其文件构建在与 SConscript 文件相同的目录中它的士兵。应用程序成功地构建了 Prj2 依赖项和自身。但是，您无法运行生成的 EXE，因为它在其他目录中找不到所需的库。

问题

如何让多个具有依赖关系的项目将其二进制文件和调试信息输出到一个公共(public)目录中，以便它们可以执行和调试？

可能的解决方案

这是我目前想到的:

我尝试使用 VariantDir(以前称为 BuildDir)，但这似乎不起作用。也许我在这里搞砸了。
我可能会明确地告诉编译器和链接器(例如通过 Fo/Fd)将文件放在哪里(这是最好的还是唯一的解决方案？？？)
对生成的二进制文件执行复制命令(这似乎是一种 hack，管理/维护相当麻烦)

更新

我更新了下面的文件结构和文件内容，以完整反射(reflect)工作解决方案。感谢 grieve 的洞察力。

命令

使用此配置，不幸的是，您必须通过 cd'ing 到构建目录然后运行以下命令来执行构建。我需要一个正常工作的别名设置来解决这个问题。


build> scons ../bin/project1.exe

文件结构

    /scons-sample
       /bin
          /release
          /debug
       /build
           SConstruct
           scons_helper.py
       /prj1
           SConscript
           /include
           /src
              main.cpp
       /prj2
          SConscript
          /include
             functions.h
          /src
             functions.cpp

S构造


import os.path

BIN_DIR = '../bin'
OBJ_DIR = './obj'

#--------------------------------------
#            CxxTest Options
#--------------------------------------
CXXTEST_DIR = '../extern/CxxTest/CxxTest-latest'
PERL = 'perl -w'
TESTS = '*.h'
TESTGEN = PERL + CXXTEST_DIR + '/cxxtestgen.pl'
CXXTESTGEN_FLAGS = '--runner=ParenPrinter \
                    --abort-on-fail \
                    --have-eh'

#--------------------------------------
#            Options
#--------------------------------------
SetOption( 'implicit_cache', 1 )

# command line options
opts = Options()
opts.AddOptions(
EnumOption(
            'debug',
            'Debug version (useful for developers only)',
            'no',
            allowed_values = ('yes', 'no'),
            map = { },
            ignorecase = 1
        )
)

#--------------------------------------
#           Environment
#--------------------------------------
env = Environment( 

    options = opts,

    #--------------------------------------
    #           Linker Options
    #--------------------------------------
    LIBPATH = [
                '../extern/wxWidgets/wxWidgets-latest/lib/vc_dll'
              ],

    LIBS =  [
               # 'wxmsw28d_core.lib',
               # 'wxbase28d.lib',
               # 'wxbase28d_odbc.lib',
               # 'wxbase28d_net.lib',
                'kernel32.lib',
                'user32.lib',
                'gdi32.lib',
                'winspool.lib',
                'comdlg32.lib',
                'advapi32.lib',
                'shell32.lib',
                'ole32.lib',
                'oleaut32.lib',
                'uuid.lib',
                'odbc32.lib',
                'odbccp32.lib'
            ],

    LINKFLAGS = '/nologo /subsystem:console /incremental:yes /debug /machine:I386',

    #--------------------------------------
    #           Compiler Options
    #--------------------------------------
    CPPPATH = [
                './include/', 
                '../extern/wxWidgets/wxWidgets-latest/include',
                '../extern/wxWidgets/wxWidgets-latest/vc_dll/mswd'
               ],

    CPPDEFINES = [ 
                    'WIN32',
                    '_DEBUG',
                    '_CONSOLE',
                    '_MBCS',
                    'WXUSINGDLL',
                    '__WXDEBUG__'
                 ],

    CCFLAGS = '/W4 /EHsc /RTC1 /MDd /nologo /Zi /TP /errorReport:prompt'
)

env.Decider( 'MD5-timestamp' )        # For speed, use timestamps for change, followed by MD5
Export( 'env', 'BIN_DIR' )          # Export this environment for use by the SConscript files

#--------------------------------------
#           Builders
#--------------------------------------
SConscript( '../prj1/SConscript' )
SConscript( '../prj2/SConscript' )
Default( 'prj1' )

scons_helper.py


import os.path

#--------------------------------------
#            Functions
#--------------------------------------

# Prepends the full path information to the output directory so that the build
# files are dropped into the directory specified by trgt rather than in the 
# same directory as the SConscript file.
# 
# Parameters:
#   env     - The environment to assign the Program value for
#   outdir  - The relative path to the location you want the Program binary to be placed
#   trgt    - The target application name (without extension)
#   srcs    - The list of source files
# Ref:
#   Credit grieve and his local SCons guru for this: 
#   http://stackoverflow.com/questions/279860/how-do-i-get-projects-to-place-their-build-output-into-the-same-directory-with
def PrefixProgram(env, outdir, trgt, srcs):
    env.Program(target = os.path.join(outdir, trgt), source = srcs)

# Similar to PrefixProgram above, except for SharedLibrary
def PrefixSharedLibrary(env, outdir, trgt, srcs):
    env.SharedLibrary(target = os.path.join(outdir, trgt), source = srcs)

def PrefixFilename(filename, extensions):
    return [(filename + ext) for ext in extensions]

# Prefix the source files names with the source directory
def PrefixSources(srcdir, srcs):
    return  [os.path.join(srcdir, x) for x in srcs]

Prj1 的 SConscript


import os.path
import sys
sys.path.append( '../build' )
from scons_helper import *

Import( 'env', 'BIN_DIR' )        # Import the common environment

prj1_env = env.Clone()          # Clone it so we don't make changes to the global one

#--------------------------------------
#           Project Options
#--------------------------------------
PROG = 'project1'

#--------------------------------------
#            Header Files
#--------------------------------------
INC_DIR = [
            '../prj2/include'
          ]

HEADERS = [
            ''
          ]

#--------------------------------------
#            Source Files
#--------------------------------------
SRC_DIR = './src'
SOURCES = [
            'main.cpp'
          ]
# Prefix the source files names with the source directory
SOURCES = PrefixSources( SRC_DIR, SOURCES )

#--------------------------------------
#      Compiler and Linker Overrides
#--------------------------------------
prj1_env.Append(
    CPPPATH = INC_DIR,
    LIBS = 'project2',
    LIBPATH = BIN_DIR,

    # Microsoft Visual Studio Specific
    PDB = os.path.join( BIN_DIR, PROG + '.pdb' )
)

#--------------------------------------
#            Builders
#--------------------------------------
PrefixProgram( prj1_env, BIN_DIR, PROG, SOURCES )

Prj2 的 SConscript


import os.path   
import sys
sys.path.append( '../build' )
from scons_helper import *

Import( 'env', 'BIN_DIR' )        # Import the common environment

prj2_env = env.Clone()          # Clone it so we don't make changes to the global one

#--------------------------------------
#           Project Options
#--------------------------------------
PROG = 'project2'

#--------------------------------------
#            Header Files
#--------------------------------------
INC_DIR = [
             ''
          ]
HEADERS = [
            'functions.h'
          ]

#--------------------------------------
#            Source Files
#--------------------------------------
SRC_DIR = './src/'
SOURCES = [
            'functions.cpp'
          ]
# Prefix the source files names with the source directory
SOURCES = PrefixSources( SRC_DIR, SOURCES )

#--------------------------------------
#      Compiler and Linker Overrides
#--------------------------------------
# Update the environment with the project specific information
prj2_env.Append(
    CPPPATH = INC_DIR,

    # Microsoft Visual Studio Specific
    PDB = os.path.join( BIN_DIR, PROG + '.pdb' )
)

#--------------------------------------
#               Builders
#--------------------------------------
PrefixSharedLibrary( prj2_env, BIN_DIR, PROG, SOURCES )

最佳答案

好的第三次尝试是一种魅力。我只是把它放在一个新的答案中，以保持它更干净。我和我本地的 scons 大师谈过，他说安装方法应该可以工作，但是有一个更简单的方法。

只需定义您希望可执行文件(或 dll)所在的完整路径。所以:

prj2_env.Program(target = os.path.join(BIN_DIR,PROG), source = SOURCES )

如果您不想在所有地方都这样做，您可以创建一个全局函数:

def PrefixProgram(env, trgt, srcs):
    env.Program(target = os.path.join(env.["MY_OUTPUT_DIR"], trgt), source = srcs)

然后在你的 SConscript 中，类似:

import ('PrefixProgram')
# stuff ...
PrefixProgram(prj2_env, PROG, SOURCES)

请注意，您可以将自己的属性添加到环境中，这就是

env["MY_OUTPUT_DIR"]

来自。我即兴写了这个，所以期待一些小的语法错误，什么不是。显然，您可以对共享库和静态库应用相同的技巧。

为了全面披露，我让我本地的 scons 大师有机会亲自回答这个问题，但他害怕自己会沉迷于该网站并拒绝了。 :)

关于c++ - 如何让项目将其构建输出与 Scons 放在同一目录中？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/279860/

c++ - 如何让项目将其构建输出与 Scons 放在同一目录中？

背景

问题

可能的解决方案

更新

命令

文件结构

S构造

Prj1 的 SConscript

Prj2 的 SConscript

上一篇：ios - 如何让 xcode 在依赖项之前运行脚本？

下一篇：cordova - ionic 构建 : difference between --prod and --release flags?