delphi - 对于大字符串，TSQLQuery 仅正确传输前 1MB 数据

标签 delphi stream sql-server-2008-r2 delphi-xe2

(请参阅文章末尾使用堆栈跟踪编辑 #1 和使用解决方法编辑 #2)

在对 TSQLQuery.FieldByName().AsString -> TStringStream Corrupts Data 进行故障排除时，我发现 TSQLQuery.FieldByName().AsBytes 只能正确传输 1MB 的 varchar(max) 数据。

  • 使用 WireShark，我验证了数据全部都正确传送到了 Delphi 应用程序。
  • 我确认它始终将正确的字节数写入输出文件，但任何超过正好 1MB 的字节都是空字节。
  • 此外，TSQLQuery.FieldByName().AsString 和 .AsWideString 也表现出相同的行为。

什么会导致.AsBytes向TFileStream提供正确的字节数，但null所有超过1MB的字节？

测试用例

此测试用例创建两个输出文件。 Plus14.txt 为 1MB + 14 字节。 Plus36.txt 为 1MB + 36 字节。在这两种情况下，超过 1MB 的字节都是 null 字节值。我什至尝试过 16MB 的字符串。输出文件的前 1MB 是正确的；接下来的 15MB 都是 null 字节。

SQL 服务器

use tempdb
go
create procedure RunMe
as
  declare @s1 varchar(max), @s2 varchar(max)

  set @s1 = '0123456789ABCDEF'
  set @s2 = @s1 + @s1 + @s1 + @s1 + @s1 + @s1 + @s1 + @s1 -- 128 bytes
  set @s1 = @s2 + @s2 + @s2 + @s2 + @s2 + @s2 + @s2 + @s2 -- 1,024 bytes
  set @s2 = @s1 + @s1 + @s1 + @s1 + @s1 + @s1 + @s1 + @s1 -- 8,192 bytes
  set @s1 = @s2 + @s2 + @s2 + @s2 + @s2 + @s2 + @s2 + @s2 -- 65,536 bytes
  set @s2 = @s1 + @s1 + @s1 + @s1 + @s1 + @s1 + @s1 + @s1 -- 524,288 bytes
  set @s1 = @s2 + @s2                                     -- 1,048,576 bytes

  set @s2 = @s1 + 'this is a test'                        -- 1MB + 14 bytes
  set @s1 = @s1 + 'of the emergency broadcasting system'  -- 1MB + 36 bytes

  select @s2 as Plus14, @s1 as Plus36
go
grant execute on RunMe to public
go

德尔福 DFM

默认表单，将 TSQLConnection 拖放到其上(以及一个 TButton):

object SQLConnection1: TSQLConnection
  DriverName = 'MSSQL'
  GetDriverFunc = 'getSQLDriverMSSQL'
  LibraryName = 'dbxmss.dll'
  LoginPrompt = False
  Params.Strings = (
    'User_Name=user'
    'Password=password'
    'SchemaOverride=%.dbo'
    'DriverUnit=Data.DBXMSSQL'

      'DriverPackageLoader=TDBXDynalinkDriverLoader,DBXCommonDriver160.' +
      'bpl'

      'DriverAssemblyLoader=Borland.Data.TDBXDynalinkDriverLoader,Borla' +
      'nd.Data.DbxCommonDriver,Version=16.0.0.0,Culture=neutral,PublicK' +
      'eyToken=91d62ebb5b0d1b1b'

      'MetaDataPackageLoader=TDBXMsSqlMetaDataCommandFactory,DbxMSSQLDr' +
      'iver160.bpl'

      'MetaDataAssemblyLoader=Borland.Data.TDBXMsSqlMetaDataCommandFact' +
      'ory,Borland.Data.DbxMSSQLDriver,Version=16.0.0.0,Culture=neutral' +
      ',PublicKeyToken=91d62ebb5b0d1b1b'
    'GetDriverFunc=getSQLDriverMSSQL'
    'LibraryName=dbxmss.dll'
    'VendorLib=sqlncli10.dll'
    'VendorLibWin64=sqlncli10.dll'
    'HostName=localhost'
    'Database=tempdb'
    'MaxBlobSize=-1'
    'LocaleCode=0000'
    'IsolationLevel=ReadCommitted'
    'OSAuthentication=False'
    'PrepareSQL=True'
    'BlobSize=-1'
    'ErrorResourceFile='
    'OS Authentication=True'
    'Prepare SQL=False')
  VendorLib = 'sqlncli10.dll'
  Left = 8
  Top = 8
end

德尔福PAS

TButton.OnClick 的代码:

procedure TForm1.Button1Click(Sender: TObject);
var qry: TSQLQuery;

  procedure save(str: string);
  var data: TBytes; fs: TFileStream;
  begin
    fs := TFileStream.Create(Format('c:\%s.txt', [str]), fmCreate);
    try
      data := qry.FieldByName(str).AsBytes;
      if data <> nil then
        fs.WriteBuffer(data[0], Length(data));
    finally
      FreeAndNil(fs);
    end;
  end;

begin
  SQLConnection1.Open;
  qry := TSQLQuery.Create(nil);
  try
    qry.MaxBlobSize := -1;
    qry.SQLConnection := SQLConnection1;
    qry.SQL.Text := 'set nocount on; exec RunMe';
    qry.Open;
    save('Plus14');
    save('Plus36');
  finally
    FreeAndNil(qry);
  end;
  SQLConnection1.Close;
end;

<<< 编辑 #1 - 堆栈跟踪 >>>

我追踪了 Embarcadero 的代码，找到了 null 字节首次出现的位置。

  • FMethodTable.FDBXRow_GetBytes
  • Data.DBXDynalink.TDBXDynalinkByteReader.GetBytes(0,0,(...),0,1048590,True)
  • Data.SqlExpr.TCustomSQLDataSet.GetFieldData(1,$7EC80018)
  • Data.SqlExpr.TCustomSQLDataSet.GetFieldData(???,$7EC80018)
  • Data.DB.TDataSet.GetFieldData($66DB18,$7EC80018,True)
  • Data.SqlExpr.TSQLBlobStream.ReadBlobData
  • Data.SqlExpr.TSQLBlobStream.Read((无值),1048590)
  • System.Classes.TStream.ReadBuffer((无值),1048590) 1MB + 14b
  • Data.DB.TBlobField.GetAsBytes
  • Unit1.save('Plus14')

当FDBXRow_GetBytes返回时，Value: TBytes为1048590字节，并为最后14个字节设置null值。

我不知道下一步该尝试什么。非常感谢任何帮助。

<<< 编辑 #2 - 解决方法 >>>

我设置了SQLConnection1.MaxBlobSize := 2097152，现在所有字节都正确地流式传输到输出文件。因此，该问题似乎仅在 .MaxBlobSize = -1 时发生。

既然我找到了解决方法，解决问题的紧迫性就消失了。但是，如果可能的话，我仍然希望让 -1 工作，因为我的数据库中的值有时会超过 50 兆。因此，任何建议或帮助仍然值得赞赏。

<<< 编辑 #3 - 错误报告 >>>

我向 Embarcadero (QC#108475) 提交了错误报告。一旦错误被确认/修复，我会报告。

<<< 编辑 #4 - 升级的错误报告 >>>

我今天发现，使用此解决方法有时会导致 TClientDataSet 抛出带有文本“灾难性故障”的 EOleException。显然，TClientDataSet 更喜欢 MaxBlobSize := '-1';。因此，我升级了 Embarcadero 的错误报告。希望他们很快就能为此提供修复或更好的解决方法。

最佳答案

我能够解决这个问题。可以像这样设置 TSQLConnection 属性:

sqlcon.Params.Values['MaxBlobSize'] := '250000000'; // 250 megs
sqlcon.Params.Values['BlobSize'] := '-1';

但我通过使用 DBXRegDB 单元设置所有 TSQLConnection 组件，设置了比这些更多的属性。我不使用 IDE 的属性编辑器...可能还需要 DBXRegDB 单元中的一些设置才能使解决方法发挥作用(我不确定)。我将包含 DBXRegDB 单元以及如何使用它的说明，以防万一。

  • 将 DBXRegDB 单元添加到 .dpr 文件中。
  • 将 DBXRegDB 添加到表单的 uses 子句中。
  • 执行以下代码，并向其传递表单上的 TSQLConnection 组件:

.

procedure SetupMSSqlConnection(const sqlcon: TSQLConnection; const hostname, port, maxcon, dbname, username, password: string);
begin
  sqlcon.Params.Clear;
  sqlcon.DriverName := 'MSSQL_Con';
  sqlcon.VendorLib := sqlcon.Params.Values[TDBXPropertyNames.VendorLib];
  sqlcon.LibraryName := sqlcon.Params.Values[TDBXPropertyNames.LibraryName];
  sqlcon.GetDriverFunc := sqlcon.Params.Values[TDBXPropertyNames.GetDriverFunc];

  sqlcon.Params.Values[TDBXPropertyNames.HostName] := hostname;
  sqlcon.Params.Values[TDBXPropertyNames.Port]     := port;
  sqlcon.Params.Values[TDBXPropertyNames.Database] := dbname;
  sqlcon.Params.Values[TDBXPropertyNames.UserName] := username;
  sqlcon.Params.Values[TDBXPropertyNames.Password] := password;
end;

最后，将 TSQLQuery.MaxBlobSize 设置为“0”，以便它自动从其 TSQLConnection 复制值。

这里是DBXRegDB单元，供那些想要使用它的人使用。我根据我在这里找到的内容改编了它:DBX without deploying DBXDrivers.ini 。确保没有将 BlobSize 设置为 250 兆，否则会出现内存不足错误。

unit DBXRegDB;

interface

implementation

uses
  DBXCommon, DBXDynalinkNative, DBXMSSQL, Forms, Classes;

type
  TDBXInternalDriver = class(TDBXDynalinkDriverNative)
  public
    constructor Create(DriverDef: TDBXDriverDef); override;
  end;

  TDBXInternalProperties = class(TDBXProperties)
  public
    constructor Create(DBXContext: TDBXContext); override;
  end;

{ TDBXInternalDriver }

constructor TDBXInternalDriver.Create(DriverDef: TDBXDriverDef);
begin
  inherited Create(DriverDef, TDBXDynalinkDriverLoader);
  InitDriverProperties(TDBXInternalProperties.Create(DriverDef.FDBXContext));
end;

{ TDBXInternalProperties }

constructor TDBXInternalProperties.Create(DBXContext: TDBXContext);
begin
  inherited Create(DBXContext);

  Values[TDBXPropertyNames.SchemaOverride]         := '%.dbo';
  Values[TDBXPropertyNames.DriverUnit]             := 'DBXMSSQL';
  Values[TDBXPropertyNames.DriverPackageLoader]    := 'TDBXDynalinkDriverLoader,DBXCommonDriver160.bpl';
  Values[TDBXPropertyNames.DriverAssemblyLoader]   := 'Borland.Data.TDBXDynalinkDriverLoader,Borland.Data.DbxCommonDriver,Version=15.0.0.0,Culture=neutral,PublicKeyToken=91d62ebb5b0d1b1b';
  Values[TDBXPropertyNames.MetaDataPackageLoader]  := 'TDBXMsSqlMetaDataCommandFactory,DbxMSSQLDriver160.bpl';
  Values[TDBXPropertyNames.MetaDataAssemblyLoader] := 'Borland.Data.TDBXMsSqlMetaDataCommandFactory,Borland.Data.DbxMSSQLDriver,Version=15.0.0.0,Culture=neutral,PublicKeyToken=91d62ebb5b0d1b1b';
  Values[TDBXPropertyNames.GetDriverFunc]          := 'getSQLDriverMSSQL';
  Values[TDBXPropertyNames.LibraryName]            := 'dbxmss.dll';
  Values[TDBXPropertyNames.VendorLib]              := 'sqlncli10.dll';
  Values[TDBXPropertyNames.HostName]               := 'ServerName';
  Values[TDBXPropertyNames.Database]               := 'Database Name';
  Values[TDBXPropertyNames.MaxBlobSize]            := '250000000';
  Values['LocaleCode']                             := '0000';
  Values[TDBXPropertyNames.IsolationLevel]         := 'ReadCommitted';
  Values['OSAuthentication']                       := 'False';
  Values['PrepareSQL']                             := 'True';
  Values[TDBXPropertyNames.UserName]               := 'user';
  Values[TDBXPropertyNames.Password]               := 'password';
  Values['BlobSize']                               := '-1';
  Values[TDBXPropertyNames.ErrorResourceFile]      := '';
  Values['OS Authentication']                      := 'False';
  Values['Prepare SQL']                            := 'True';
  Values[TDBXPropertyNames.ConnectTimeout]         := '30';
end;

var
  InternalConnectionFactory: TDBXMemoryConnectionFactory;

initialization

  TDBXDriverRegistry.RegisterDriverClass('MSSQL_Con', TDBXInternalDriver);
  InternalConnectionFactory := TDBXMemoryConnectionFactory.Create;
  InternalConnectionFactory.Open;
  TDBXConnectionFactory.SetConnectionFactory(InternalConnectionFactory);

end.

关于delphi - 对于大字符串，TSQLQuery 仅正确传输前 1MB 数据，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/12225450/

上一篇：json - Delphi: super 对象序列化自定义转换器/逆变器

下一篇：delphi - 当字符串中有名称时使用指针

相关文章：

SQL Select 在秒范围内

SQL Server 日期时间转换问题

delphi - 线程应用程序中的 Indy 错误!

delphi - 在Delphi中使用DBExpress创建数据库？

file - ffmpeg:哪些文件格式支持标准输入使用？

android - 如何将 ExifInterface 与流或 URI 一起使用

Delphi 7 - 如何用画笔填充圆角矩形？

Delphi - 在 dataset.enablecontrols 上的 TDBGrid 内部触发什么事件

c - Padding - 加密算法

sql-server - 如何将空日期变量传递到 SQL Server 数据库

©2024 IT工具网  联系我们