delphi - 如何获取高DPI系统下的真实屏幕分辨率？

Question

因此，Delphi 程序不支持 DPI。直到最近当我需要高 DPI 的计算机中的真实屏幕分辨率( Wrong resolution reported by Screen.Width when "Make it easier to read what's on screen" is 150% )时，这才让我感到困扰。一些建议是使应用程序具有高 DPI 意识(XML list )，但其他人警告我们这涉及大量工作!因此，由于懒惰(或缺乏时间)，我想知道是否有计算真实分辨率的技巧。

我想到的一个非常肮脏的技巧是创建一个支持 DPI 的配套工具(小型控制台应用程序)。我所要做的就是调用这个工具并从中获取真正的分辨率。 非常斯巴达，但应该可以。不管怎样，一定有更好的方法来做到这一点!

Answer 1

Win32_DesktopMonitor WMI 类将产生信息。

例如，使用取自此处的代码:Delphi7: Get attached monitor properties

{$APPTYPE CONSOLE}

uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;

function VarStrNull(VarStr: OleVariant): string;
// dummy function to handle null variants
begin
  Result := '';
  if not VarIsNull(VarStr) then
    Result := VarToStr(VarStr);
end;

procedure GetMonitorInfo;
var
  objWMIService: OleVariant;
  colItems: OleVariant;
  colItem: OleVariant;
  oEnum: IEnumvariant;
  iValue: LongWord;

  function GetWMIObject(const objectName: String): IDispatch;
  var
    chEaten: Integer;
    BindCtx: IBindCtx;
    Moniker: IMoniker;
  begin
    OleCheck(CreateBindCtx(0, BindCtx));
    OleCheck(MkParseDisplayName(BindCtx, StringToOleStr(objectName), chEaten,
      Moniker));
    OleCheck(Moniker.BindToObject(BindCtx, nil, IDispatch, Result));
  end;

begin
  objWMIService := GetWMIObject('winmgmts:\\localhost\root\CIMV2');
  colItems := objWMIService.ExecQuery
    ('SELECT * FROM Win32_DesktopMonitor', 'WQL', 0);
  oEnum := IUnknown(colItems._NewEnum) as IEnumvariant;
  while oEnum.Next(1, colItem, iValue) = 0 do
  begin
    Writeln('Caption      ' + VarStrNull(colItem.Caption));
    Writeln('Device ID    ' + VarStrNull(colItem.DeviceID));
    Writeln('Width        ' + VarStrNull(colItem.ScreenWidth));
    Writeln('Height       ' + VarStrNull(colItem.ScreenHeight));
    Writeln;
  end;
end;

begin
  try
    CoInitialize(nil);
    try
      GetMonitorInfo;
      Readln;
    finally
      CoUninitialize;
    end;
  except
    on E: Exception do
    begin
      Writeln(E.Classname, ': ', E.Message);
      Readln;
    end;
  end;
end.

如果由于任何原因 WMI 不可用，那么您需要一个单独的 DPI 感知进程来完成这项工作。这还需要一些 IPC。

另一个问题是最近版本的 Windows 更改了这些 WMI 类的行为。您可能需要使用不同的 WMI 查询。参见这里:https://social.msdn.microsoft.com/Forums/windowsdesktop/en-US/138d387c-b222-4c9f-b3bb-c69ee890491c/problem-with-win32desktopmonitor-in-windows-8-platform?forum=windowsgeneraldevelopmentissues