multithreading - Delphi Seattle 10，多线程/核心性能

Question

我有一个 100% Delphi 代码的应用程序。它是一个 64 位 Windows 控制台应用程序，具有工作负载管理器和固定数量的工作人员。这是通过创建线程来完成的，每个线程都是一个工作线程。线程不会终止，它会从工作负载管理器填充的自己的队列中提取工作。

这似乎工作得很好。

然而，我发现在 16 核系统上，我看到处理时间约为 90 分钟(它有 2,000,000 多个工作负载；每个工作负载都进行数据库工作)。当我添加 16 到 32 个核心时，我发现性能下降了!不存在数据库争用。本质上，数据库正在等待事情发生。

每个线程都有自己的数据库连接。每个线程的查询仅使用该线程连接。

我更新了Delphi MM以使用ScaleMM2；这取得了很大的进步；但我仍然不明白为什么增加核心会降低性能。

当应用程序有 256 个线程、32 个核心时，CPU 总使用率为 80%。 当应用程序在 16 个核心上有 256 个线程时，CPU 总使用率为 100%(这就是我想添加核心的原因)——而且速度变慢了:-(

我已将尽可能多的建议应用到代码库中。

ie - 函数不返回字符串，使用 Const 作为参数，用小临界区保护“共享”数据(实际上使用多读独占写)。我目前不分配处理器关联性；我正在阅读关于使用它的相互矛盾的建议..所以我目前没有(添加起来很简单，只是今天不存在)。

问题 - 倾向于我“认为”问题是围绕线程争用......

如何确认线程争用是问题所在？是否有专门用于此类争用识别的工具？ 我如何确定什么正在使用“堆”，什么没有，以进一步减少那里的争用？

见解、指导、指点将不胜感激。

可以提供相关的代码区域......如果我知道相关的内容。

Procedure TXETaskWorkloadExecuterThread.Enqueue(Const Workload: TXETaskWorkload);
Begin
  // protect your own queue
  FWorkloadQueue.Enter;
  FWorkloads.Add(Workload);
  FWorkloadQueue.Leave;
End;

Procedure TXETaskManager.Enqueue(Const Workload: TXETaskWorkload);
Begin
  If FWorkloadCount >= FMaxQueueSize Then Begin
    WaitForEmptyQueue;
    FWorkloadCount := 0;
  End;

  FExecuters[FNextThread].Enqueue(Workload);
  // round-robin the queue
  Inc(FNextThread);
  Inc(FWorkloadCount);
  If FNextThread >= FWorkerThreads Then Begin
    FNextThread := 0;
  End;
End;


Function TXETaskWorkloadExecuterThread.Dequeue(Var Workload: TXETaskWorkload): Boolean;
Begin
  Workload := Nil;
  Result := False;

  FWorkloadQueue.Enter;
  Try
    If FNextWorkload < FWorkloads.Count Then Begin
      Workload := FWorkloads[FNextWorkload];
      Inc(FNextWorkload);
      If Workload Is TXETaskWorkLoadSynchronize Then Begin
        FreeAndNil(Workload);
        Exit;
      End;
      Result := True;
    End Else Begin
      FWorkloads.Clear;
      FNextWorkload := 0;
      FHaveWorkloadInQueue.ResetEvent;
      FEmptyAndFinishedQueue.SetEvent;
    End;
  Finally
    FWorkloadQueue.Leave;
  End;
End;

编辑---

感谢大家的评论。澄清。

此系统/VM 上没有任何其他内容。所讨论的可执行文件是唯一使用 CPU 的程序。单线程性能意味着线性。我只是将其设为分而治之。如果我有 5,000,000 辆汽车要停放，并且有 30 名司机，有 30 个不同的 parking 场。我可以告诉每个司机等待另一个司机完成 parking ，这比告诉 30 个司机同时 parking 要慢。

单线程分析表明没有任何原因导致此问题。我在这个板上看到过有关 Delphi 和多核性能“陷阱”的提及(主要与字符串处理和 LOCK 有关)。

数据库本质上是在说它很无聊，并在等待事情发生。我已经检查了英特尔 vTune 的副本。一般来说，它说……锁。但是，我找不到在哪里。在我看来，我所拥有的非常简单，并且当前的锁区域是必要的且很小。我看不到的是可能由于其他原因而发生的锁..比如创建锁的字符串，或者线程 1 通过访问该数据导致主进程出现一些问题(即使通过关键部分进行保护)。

继续研究。再次感谢您的反馈/想法。

Answer 1

您的工作负载管理器正在决定哪个线程获取哪个工作项。如果给定的线程阻塞(比如工作很长、数据库延迟等)，您就会将更多项目排队到该线程，即使它们可能暂时不会得到处理(如果有的话)。

通常，工作项应存储在单个共享队列中，然后多个线程从中提取。当任何给定线程准备就绪时，它会拉出下一个可用的工作项。例如:

constructor TXETaskManager.Create;
var
  I: Integer;
begin
  FWorkloadQueue := TCriticalSection.Create;
  FWorkloads := TList<TXETaskWorkload>.Create;
  FEmptyQueue := TEvent.Create(nil, True, True, '');
  FHaveWorkloadInQueue := TEvent.Create(nil, True, False, '');
  FNotFullQueue := TEvent.Create(nil, True, True, '');
  FTermEvent := TEvent.Create(nil, True, False, '');
  ...
  FMaxQueueSize := ...;
  FWorkerThreads := ...;
  for I := 0 to FWorkerThreads-1 do
    FExecuters[I] := TXETaskWorkloadExecuterThread.Create(Self);
end;

destructor TXETaskManager.Destroy;
begin
  for I := 0 to FWorkerThreads-1 do
    FExecuters[I].Terminate;
  FTermEvent.SetEvent;
  for I := 0 to FWorkerThreads-1 do
  begin
    FExecuters[I].WaitFor;
    FExecuters[I].Free;
  end;
  FWorkloadQueue.Free;
  FWorkloads.Free;
  FEmptyQueue.Free;
  FHaveWorkloadInQueue.Free;
  FNotFullQueue.Free;
  FTermEvent.Free;
  ...

  inherited;
end;

procedure TXETaskManager.Enqueue(Const Workload: TXETaskWorkload);
begin
  FWorkloadQueue.Enter;
  try
    while FWorkloads.Count >= FMaxQueueSize do
    begin
      FWorkloadQueue.Leave;
      FNotFullQueue.WaitFor(INFINITE);
      FWorkloadQueue.Enter;
    end;

    FWorkloads.Add(Workload);

    if FWorkloads.Count = 1 then
    begin
      FEmptyQueue.ResetEvent;
      FHaveWorkloadInQueue.SetEvent;
    end;

    if FWorkloads.Count >= FMaxQueueSize then
      FNotFullQueue.ResetEvent;
  finally
    FWorkloadQueue.Leave;
  end;
end;

function TXETaskManager.Dequeue(var Workload: TXETaskWorkload): Boolean;
begin
  Result := False;
  Workload := nil;

  FWorkloadQueue.Enter;
  try
    if FWorkloads.Count > 0 then
    begin
      Workload := FWorkloads[0];
      FWorkloads.Delete(0);
      Result := True;

      if FWorkloads.Count = (FMaxQueueSize-1) then
        FNotFullQueue.SetEvent;

      if FWorkloads.Count = 0 then
      begin
        FHaveWorkloadInQueue.ResetEvent;
        FEmptyQueue.SetEvent;
      end;
    end;
  finally
    FWorkloadQueue.Leave;
  end;
end;

constructor TXETaskWorkloadExecuterThread.Create(ATaskManager: TXETaskManager);
begin
  inherited Create(False);
  FTaskManager := ATaskManager;
end;

procedure TXETaskWorkloadExecuterThread.Execute;
var
  Arr: THandleObjectArray;
  Event: THandleObject;
  Workload: TXETaskWorkload;
begin
  SetLength(Arr, 2);
  Arr[0] := FTaskManager.FHaveWorkloadInQueue;
  Arr[1] := FTaskManager.FTermEvent;

  while not Terminated do
  begin
    case TEvent.WaitForMultiple(Arr, INFINITE, False, Event) of
      wrSignaled:
      begin
        if Event = FTaskManager.FHaveWorkloadInQueue then
        begin
          if FTaskManager.Dequeue(Workload) then
          try
            // process Workload as needed...
          finally
            Workload.Free;
          end;
        end;
      end;
      wrError: begin
        RaiseLastOSError;
      end;
    end;
  end;
end; 

如果您发现线程没有获得足够的工作，您可以根据需要调整线程数。通常，您使用的线程数不应超过可用 CPU 核心数。