我的类定义是:
TAnimal = class(TInterfacedObject)
public
constructor Create; overload;
constructor Create(param : string); overload;
end;
IAnimal = interface
procedure DoSomething;
end;
TDog = class(TAnimal, IAnimal)
public
procedure DoSomething;
end;
TCat = class(TAnimal, IAnimal)
public
procedure DoSomething;
end;
示例代码:
procedure TForm1.DogButtonPressed(Sender: TObject);
var
myDog : TDog;
I : Integer;
begin
myDog := TDog.Create('123');
I := Length(myQueue);
SetLength(myQueue, I+1);
myQueue[I] := TDog; //Probably not the way to do it...??
end;
procedure TForm1.CatButtonPressed(Sender: TObject);
var
myCat : TCat;
I : Integer;
begin
myCat := TCat.Create('123');
I := Length(myQueue);
SetLength(myQueue, I+1);
myQueue[I] := TCat; //Probably not the way to do it...??
end;
procedure TForm1.OnProcessQueueButtonPressed(Sender: TObject);
var
MyInterface : IAnimal; //Interface variable
I : Integer;
begin
for I := Low(myQueue) to High(myQueue) do
begin
MyInterface := myQueue[I].Create('123'); //Create instance of relevant class
MyInterface.DoSomething;
end;
end;
所以,假设您有一个带有三个按钮的表单。一个“Dog”按钮、一个“Cat”按钮和一个“Process Queue”按钮。当您按下“Dog”按钮或“Cat”按钮时,相关类将添加到数组中以充当队列。然后,当您按下“进程队列”按钮时,程序将逐步遍历数组,创建相关类的对象,然后调用在该类中实现的接口(interface)方法。记住上面的示例代码,如何实现这一点?
简单的方法显然是将类名作为字符串添加到字符串数组中,然后在 OnProcessQueueButtonPressed
过程中使用 if
语句,例如:
procedure TForm1.OnProcessQueueButtonPressed(Sender: TObject);
var
MyInterface : IAnimal; //Interface variable
I : Integer;
begin
for I := Low(myQueue) to High(myQueue) do
begin
if myQueue[I] = 'TDog' then
MyInterface := TDog.Create('123');
if myQueue[I] = 'TCat' then
MyInterface := TCat.Create('123');
MyInterface.DoSomething;
end;
end;
我试图避免这种情况,因为每次添加新类时,我都必须记住为新类添加 if
block 。
最佳答案
您可以使用class reference来做到这一点。像这样定义您的类引用类型:
type
TAnimalClass = class of TAnimal;
并安排TAnimal
支持接口(interface):
type
IAnimal = interface
procedure DoSomething;
end;
TAnimal = class(TInterfacedObject, IAnimal)
public
constructor Create; overload;
constructor Create(param: string); overload;
procedure DoSomething; virtual; abstract;
end;
TDog = class(TAnimal)
public
procedure DoSomething; override;
end;
TCat = class(TAnimal)
public
procedure DoSomething; override;
end;
使用数组会导致代码相当困惑。更好的是使用列表对象。
var
myQueue: TList<TAnimalClass>;
现在你可以编写这样的代码:
procedure TForm1.DogButtonPressed(Sender: TObject);
begin
myQueue.Add(TDog);
end;
procedure TForm1.CatButtonPressed(Sender: TObject);
begin
myQueue.Add(TCat);
end;
procedure TForm1.OnProcessQueueButtonPressed(Sender: TObject);
var
AnimalClass: TAnimalClass;
Animal: IAnimal;
begin
for AnimalClass in myQueue do
begin
Animal := AnimalClass.Create('123');
Animal.DoSomething;
end;
myQueue.Clear;
end;
您需要在适当的时候创建和销毁 myQueue
实例。我假设您已经知道如何做到这一点。
使用类引用时的一个更细微的差别是,您通常在基类中提供一个虚拟构造函数。这是因为当您使用类引用创建实例时,您会调用基类中声明的构造函数。如果该构造函数不是虚拟的,那么您的派生类构造函数代码将不会被执行。
当然,以这种方式使用类引用会使接口(interface)变得毫无意义。
关于arrays - 从类数组创建实例,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/35129227/