我正在一个简单的过程(而不是类中的方法)中以编程方式创建数据库连接对象。
mydb:= TUniConnection.Create(nil);
mydb.Database:= knowledge_db_name;
mydb.LoginPrompt:= False;
mydb.Username:= aaa;
mydb.Password:= bbb;
现在我需要处理与其他程序的错误和断开连接。当我尝试这样做时:
mydb.OnError:= OnConnectionError;
mydb.OnConnectionLost:= OnConnectionLost;
编译器告诉我
[DCC Error] test.pas(373): E2009 Incompatible types: 'method pointer and regular procedure'
我该如何解决这个问题? 以下是事件过程的定义:
procedure OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
procedure OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
最佳答案
如果您没有合适的类来放置事件处理程序,您可以定义一个虚拟类并使事件处理程序成为类过程
。然后,您不必创建该类的实例,但可以分配 mydb.OnError:= TMyDummyEventHandlerClass.OnConnectionError;
。
这是一个示例 - 我使用不同的事件,因为我没有 TUniConnection
但希望确保所有内容都能编译。 :-)
type
// Dummy class to hold event handlers:
TXMLEventHandlers = class
// Event handlers:
class procedure OnBeforeOpen(Sender: TObject);
class procedure OnAfterOpen(Sender: TObject);
end;
class procedure TXMLEventHandlers.OnBeforeOpen(Sender: TObject);
begin
MessageBox(0, PChar(ClassName + '.OnBeforeOpen'), nil, 0)
end;
class procedure TXMLEventHandlers.OnAfterOpen(Sender: TObject);
begin
MessageBox(0, PChar(ClassName + '.OnAfterOpen'), nil, 0)
end;
procedure Test;
var
xml: TXMLDocument;
begin
xml := TXMLDocument.Create(nil);
try
// Note: No instance of `TXMLEventHandlers` must be created:
xml.AfterOpen := TXMLEventHandlers.OnAfterOpen;
xml.BeforeOpen := TXMLEventHandlers.OnBeforeOpen;
xml.Active := True; // Calls the two event handlers
finally
xml.Free;
end;
end;
关于delphi - 用常规程序处理类事件(Delphi),我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/11083336/