delphi - 从源代码构建 Inno-Setup 时访问新属性/属性？

Question

我在从源代码构建 Inno Setup 时遇到了一些问题。我想修改 TNewButton 类型以在设置按钮中添加更多功能。例如，我更改了类型声明

TNewButton = class(TButton)
protected
  procedure CreateParams(var Params: TCreateParams); override;
end;

到

TNewButton = class(TButton)
  procedure CMDialogChar( var Msg: TCMDialogChar); message cm_DialogChar;
private
  FNoShortcut : Boolean;
protected
  procedure CreateParams(var Params: TCreateParams); override;
public
  property NoShortcut : Boolean read FNoShortcut write FNoShortcut;
end;

因此，我创建了一个私有(private)属性 NoShort，它通过公共(public)属性 NoShortcut 访问，并在过程 CMDialogChar 中使用(我想在特定情况下禁用，可以通过快捷方式激活按钮)。我还想实现一些其他的东西，但它们会导致同样的问题:

我可以通过这些修改编译 Inno Setup，没有任何问题(我使用 Delphi 2009 来获得 unicode 支持)，并且还可以创建安装程序。但是，当我尝试访问 .iss 文件中的新属性 NoShortcut(例如“WizardForm.NextButton.NoShortcut := true;”)时，Inno 编译器会停止并出现错误

Unknown Identifier 'NOSHORTCUT'

我是否必须以特殊方式注册这些新属性和属性才能在我的 iss 文件中使用它们？任何帮助将不胜感激:D

Answer 1

正如 TLama 指出的那样，新标识符必须在 ScriptClasses_C.pas 和 ScriptClasses_R.pas 中注册。更具体地说明问题:

在ScriptClasses_C.pas中，我创建了一个过程RegisterTNewButton_C来让编译器知道我的按钮的新标识符:

procedure RegisterTNewButton_C(Cl: TPSPascalCompiler);
begin
  with Cl.AddClassN(Cl.FindClass('TButton'), 'TNewButton') do
  begin
    RegisterProperty('NoShortcut', 'Boolean', iptrw);
  end;
end;

在 ScriptClasses_R.pas 中，我基本上做了同样的事情，但我还必须为新标识符实现 getter 和 setter:

procedure TNewButtonNoShortcut_R(Self: TNewButton; var T: Boolean); 
begin 
  T := Self.NoShortcut;
end;

procedure TNewButtonNoShortcut_W(Self: TNewButton; const T: Boolean); 
begin 
  Self.NoShortcut := T; 
end;

procedure RegisterTNewButton_R(CL: TPSRuntimeClassImporter);
begin
  with CL.Add(TNewButton) do
  begin
    RegisterPropertyHelper(@TNewButtonNoShortcut_R,@TNewButtonNoShortcut_W,'NoShortcut');
  end;
end;

为了使其最终工作，必须在 ScriptClassesLibraryRegister_C 方法中调用 RegisterTNewButton_C 并相应地在 ScriptClassesLibraryRegister_R 中调用 RegisterTNewButton_R .

此外，我还删除/注释了之前注册 TNewButton 的行(在 RegisterBidiCtrls_C 和 RegisterBidiCtrls_R 中)，以避免组件注册两次时可能出现的错误。但不知道有没有必要。