我正在尝试在运行时以表单定义 ClientDataSet 组件。我可以在 VCL 表单程序中成功定义所有字段并操作 ClientDataSet,但是当我尝试向代码中添加 AfterInsert 等事件的事件处理程序时,编译器反对我的格式。
在此过程中创建 clientDataset:
procedure TForm1.CreateNestedDataSets;
begin
cdsTables := TClientDataSet.Create(Self);
cdsNotes := TClientDataSet.Create(cdsTables); //nested dataset
//Define Tables
with TFloatField.Create(Self) do
begin
Name := 'TblID';
FieldKind := fkData;
FieldName := 'ID';
DataSet := cdsTables;
Required := True;
end;
... //define other fields for cdsTables & nested clientdataset cdsNotes
cdsNotes.AfterInsert := cdsNotesAfterInsert(cdsNotes: TDataSet);
//Create the ClientDataSet and its nested datasets
cdsTables.CreateDataSet;
//This is problem code line:
cdsNotes.AfterInsert := cdsNotesAfterInsert;
//Configure the DataSources
dsTables.DataSet := cdsTables;
dsNotes.DataSet := cdsNotes;
end;
各种论坛讨论都提出了诸如此示例之类的方法:
MyLabel := TLabel.Create(self);
MyLabel.OnClick := MyLabelClick;
在 AfterInsert 的情况下,包含一个参数。如果我在设计时生成事件,Delphi 会生成:
procedure TForm1.ClientDataSet1AfterInsert(DataSet: TDataSet);
尝试复制上面的建议时,我尝试了这种方法,该方法会生成编译器错误:
cdsNotes.AfterInsert := cdsNotesAfterInsert;
不兼容类型参数列表不同
其他格式也会产生错误:
cdsNotes.AfterInsert := cdsNotesAfterInsert(DataSet: TDataSet);
实际参数过多
我尝试了其他带有各种错误消息的变体。这是我第一次尝试定义事件,我不确定我是否理解如何处理声明。我相信我声明的实现事件“cdsNotesAfterInsert”的实际过程不需要任何参数,因为它是绑定(bind)的
到客户端数据集 cdsNotes。如果我错了,请纠正我。
这是包含违规代码的完整表单单元
unit ForumTest;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Data.DB, DBClient;
type
TForm1 = class(TForm)
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
cdsTables : tclientDataset;
cdsNotes :tclientDataset;
procedure CreateNestedDataSets;
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.CreateNestedDataSets;
begin
cdsTables := TClientDataSet.Create(Self);
cdsNotes := TClientDataSet.Create(cdsTables);
//Define Tables
with TFloatField.Create(Self) do
begin
Name := 'TblID';
FieldKind := fkData;
FieldName := 'ID';
DataSet := cdsTables;
Required := True;
end;
with TFloatField.Create(Self) do
begin
Name := 'TblParentID';
FieldKind := fkData;
FieldName := 'Parent';
DataSet := cdsTables;
Required := false;
end;
with TStringField.Create(Self) do
begin
Name := 'TblTitle';
FieldKind := fkData;
FieldName := 'Title';
Size := 40;
DataSet := cdsTables;
Required := True;
end;
with TStringField.Create(Self) do
begin
Name := 'TblFilename';
FieldKind := fkData;
FieldName := 'Filename';
Size := 80;
DataSet := cdsTables;
Required := False;
end;
//Note: For TDataSetFields, FieldKind is fkDataSet by default
with TDataSetField.Create(Self) do
begin
Name := 'TblNotes';
FieldName := 'NestedDataSet';
DataSet := cdsTables;
end;
//Define Notes
cdsNotes.DataSetField := TDataSetField(FindComponent('TblNotes'));
with TFloatField.Create(Self) do
begin
Name := 'NoteID';
FieldKind := fkData;
FieldName := 'Note ID';
DataSet := cdsNotes;
Required := True;
end;
with TStringField.Create(Self) do
begin
Name := 'NoteTxt';
FieldKind := fkData;
FieldName := 'Notes';
DataSet := cdsNotes;
Size := 40;
end;
cdsNotes.AfterInsert := cdsNotesAfterInsert(cdsNotes: TDataSet);
//Create the ClientDataSet and its nested datasets
cdsTables.CreateDataSet;
//Configure the DataSources
dsTables.DataSet := cdsTables;
dsNotes.DataSet := cdsNotes;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
CreateNestedDataSets;
end;
end.
最佳答案
这专门是为了回答您关于如何将一些自写代码分配给 TClientDataSet 的 AfterInsert 事件属性的观点。
如果您在联机帮助中查找 TClientDataSet.AfterInsert,您会发现它被定义为 TDataSetNotifyEvent,而 TDataSetNotifyEvent 又被定义为
type TDataSetNotifyEvent = procedure(DataSet: TDataSet) of object
对象
的意义在于该过程必须是一个对象的方法(读作“类”),而不是一个独立的过程/正如您在评论中所描述的方法。
为了与 TDataSetNotifyEvent 赋值兼容,您的过程需要有一个匹配的代码“签名”,也就是说,它必须是类的过程(而不是类的函数)并且具有完全相同的参数,在本例中为单个 TDataSet 参数。
因此,将所有这些放在一起,您所需要的就是类似
type
TForm1 = class(TForm)
ClientDataSet1: TClientDataSet;
procedure FormCreate(Sender: TObject);
protected
procedure MyInsertHandler(ADataSet : TDataSet);
end;
[...]
procedure TForm1.FormCreate(Sender: TObject);
begin
ClientDataSet1.AfterInsert := MyInsertHandler;
end;
procedure TForm1.MyInsertHandler(ADataSet: TDataSet);
begin
// Your code goes here, e.g.
Caption := ADataSet.Name + ' after insert';
end;
就这么简单。
关于delphi - 在运行时使用 tclientdataset 组件的参数声明事件处理程序的正确方法是什么,我们在Stack Overflow上找到一个类似的问题: https://stackoverflow.com/questions/49327523/