Delphi:使用 [weak] 属性的对象聚合和内存泄漏

Question

我想通过使用聚合来构建一个包含多个子对象的类TParent。有些对象是独立的，而有些对象也可能依赖于其他子对象。所有子对象都必须有对父对象的引用。我还想尽可能使用接口(interface)。

为此，我将 TInterfacedObject 用于 TParent，将 TAggregateObject 用于子级。由于 child 和 parent 都互相了解，我使用弱引用以避免循环依赖。事实上，此行为已在 TAggreatedObject 中定义。当我仅使用独立子对象 (TIndependantChild) 时，一切正常。

当子对象也依赖于其他子对象时，就会出现问题，请参阅TDependantChild的构造函数。我将对另一个子对象的引用存储在 fChild 变量中，该变量标有 Delphi 10 Berlin 中引入的 [weak] 属性。 FastMM4 在关闭时报告内存泄漏:

还会导致 System.TMonitor.Destroy 引发访问冲突，但这仅在使用 FastMM4 且 ReportMemoryLeaksOnShutDown 为 True 时才会发生。

program Project1;

{$APPTYPE CONSOLE}

uses
  FastMM4,
  System.SysUtils;

type
  IParent = interface
  ['{B11AF925-C62A-4998-855B-268937EF30FB}']
  end;

  IChild = interface
  ['{15C19A4E-3FF2-4639-8957-F28F0F44F8B4}']
  end;

  TIndependantChild = class(TAggregatedObject, IChild)
  end;

  TDependantChild = class(TAggregatedObject, IChild)
  private
    [weak] fChild: IChild;
  public
    constructor Create(const Controller: IInterface; const AChild: IChild); reintroduce;
  end;

  TParent = class(TInterfacedObject, IParent)
  private
    fIndependantChild: TIndependantChild;
    fDependantChild: TDependantChild;
  public
    constructor Create;
    destructor Destroy; override;
  end;

{ TParent }

constructor TParent.Create;
begin
  fIndependantChild := TIndependantChild.Create(Self);
  fDependantChild := TDependantChild.Create(Self, fIndependantChild);
end;

destructor TParent.Destroy;
begin
  fDependantChild.Free;
  fIndependantChild.Free;
  inherited;
end;

{ TDependantChild }

constructor TDependantChild.Create(const Controller: IInterface; const AChild: IChild);
begin
  inherited Create(Controller);
  fChild := AChild;
end;

var
  Owner: IParent; 

begin
  ReportMemoryLeaksOnShutDown := True;
  Owner := TParent.Create;
  Owner := nil;
end.

我发现，使用[unsafe]代替[weak]可以解决问题，但是根据delphi help

It ([unsafe]) should be only used outside the System unit in very rare situations.

因此，我不相信我应该在这里使用 [unsafe] ，特别是当我不明白会发生什么时。

那么，这种情况下内存泄漏的原因是什么以及如何克服它们？

Answer 1

使用外部 FastMM4 内存管理器时出现的泄漏和崩溃问题与以下有关用于跟踪弱引用的内部 HashMap 的最终确定的问题有关。

[REGRESSION XE2/10.1 Berlin] Unable to use 3rd party memory managers

由于该问题，无法在 Delphi 10.1 及更高版本(包括外部 FastMM4)中使用第 3 方内存管理器进行泄漏检测。

这就是为什么您遇到 [weak] 属性问题而 [unsafe] 没有问题的原因。

<小时/>

就您的代码而言，您可以在上述场景中安全地使用[unsafe]。虽然文档中有关于使用 [unsafe] 属性的警告，但该警告实际上并没有解释为什么不应使用 [unsafe]。

长话短说，当[unsafe]引用所引用的对象实例的生命周期长于引用本身的生命周期时，您可以使用[unsafe]属性。

换句话说，您必须确保在它指向的对象实例被释放后，您不会访问[unsafe]引用，仅此而已。

[unsafe]引用在其指向的对象被销毁时不会被清零，并且在对象消失后使用此类引用将导致访问冲突异常。

为了使您呈现的代码具有正确的功能，您只需将 [weak] 属性替换为 [unsafe] 即可。

  TDependantChild = class(TAggregatedObject, IChild)
  private
    [unsafe] fChild: IChild;