windows - 为什么在其搜索字符串中包含变量扩展的 `findstr` 在涉及管道时会返回意外结果？

Question

在尝试提供 comprehensive answer 时问题Why is FindStr returning not-found ，我遇到了涉及管道的奇怪代码行为。这是一些基于原始问题的代码(将在 batch-file 中执行):

rem // Set variable `vData` to literally contain `...;%main%\Programs\Go\Bin`:
set "vData=...;%%main%%\Programs\Go\Bin"
set "main=C:\Main"

echo/%vData%| findstr /I /C:"%%main%%\\Programs\\Go\\Bin"

这不返回一个匹配项，因此没有回显和ErrorLevel变为设置为 1。

虽然当我逐步完成解析过程时，我得出了相反的结论，我确实期望匹配和 0 的 ErrorLevel，因为:

1. 首先，整行被解析并立即 (%) 展开，因此 %vData% 被展开并且 %% 被替换为 %，导致将执行以下命令行:

   echo/...;%main%\Programs\Go\Bin| findstr /I /C:"%main%\\Programs\\Go\\Bin"
   

2. 管道 | 的每一侧都由 cmd/S/D c 在其自己的新 cmd 实例中执行，两者其中在 cmd 上下文中运行(这会影响 %-expansion 的处理)，导致这些部分:

   • 管道左侧:

     echo/...;C:\Main\Programs\Go\Bin
     

   • 管道右侧:

     findstr /I /C:"C:\Main\\Programs\\Go\\Bin"
     

     (findstr 最终使用的搜索字符串是 C:\Main\Programs\Go\Bin 因为 \ 被用作转义字符即使在字面搜索模式下，/C 或 /L)

如您所见，最终搜索字符串实际上出现在回显字符串中，因此我希望匹配，但命令行不返回任何结果。那么这里发生了什么，我错过了什么？

---

当我在执行管道命令行之前清除变量 main 时，我得到了预期的结果，这使我得出结论，变量 main 尽管没有扩展我上面的假设(请注意，在 cmd 上下文中，%main% 在变量为空时按字面意思保留)。我说得对吗？

---

它变得更加困惑:当我将管道的右侧放在括号之间时，返回一个匹配项，与变量 main 是否定义无关:

echo/%vData%| (findstr /I /C:"%%main%%\\Programs\\Go\\Bin")

谁能解释一下？这是否与 findstr 是一个外部命令而不是 echo 这一事实有关？ (我的意思是，break | echo/%vData% 扩展了 main 的值，如果定义的话...)

Answer 1

我将您的示例简化为:

@echo off

set "main=abc"
break | findstr /c:"111" %%main%%
break | echo findstr /c:"222" %%main%%

输出是:

FINDSTR: %main% kann nicht geöffnet werden.
findstr /c:"222" abc

这证明在管道中使用 exe 文件会导致与使用内部批处理命令不同的行为。
仅为内部命令创建一个新的 cmd.exe 实例。
这也是 findstr 不扩展百分号的原因。

这条令人困惑的行展开了，因为括号强制了一个新的 cmd.exe 实例。

break | (findstr /c:"111" %%main%%)

我会在5.3 Pipes - How does the Windows Command Interpreter (CMD.EXE) parse scripts? 修改解释