windows - 我需要仅使用 native Windows 命令匹配或替换批处理环境变量中的星号 *。这可能吗？

Question

我正在尝试从环境变量字符串中删除星号，但似乎做不到。

我正在创建一个基于搜索字符串的 m3u 文件，例如，如果我想制作一个 m3u 文件，其中包含每首带有爱这个词的歌曲，我会输入:

m3u *Love*

m3u.bat 将创建文件:

xLovex.m3u

但是替换字符的常规方法不适用于星号。 (虽然我对问号没有这个问题。)

set nam=%nam:*=x%.m3u

而是创建文件名

x.m3u

Answer 1

简单的答案是否定的。

您遇到的问题源于星号 * 在与 SET 搜索和替换方法一起使用时是一个特殊字符。它以有限但仍然有用的方式匹配多个字符。你可以了解一下 here .

硬性答案是是!

我将为您提供两种解决方案。一个不完整但优雅的解决方案， 另一个完整而不优雅。

这两种方法都会搜索 * 并将其替换为 x。
这两种方法都将搜索和修改以下字符串:

*love*

想到的第一个方法是使用“FOR/L”语句，并且要求您知道环境变量的长度是多少个字符。

::Major Edit::

I thought I knew the various maximum size strings of environmental variables, but dbenham has taken me to school, shown me a kick-in-the-behind length function, and in the mean time completely reversed my opinions of the two solutions I'm presenting.

Other than for the Windows 95/98/ME limitation of a 256 Character maximum environmental variable size. It seems that all versions of Windows using CMD.EXE have a limitation of 8,192 characters, well below what the documentation suggests.

两个版本都需要延迟环境变量扩展，但出于两个不同的原因。一是因为我在 FOR 语句中操作。另一个是因为你不能将一个 % 对放在另一个 % 对中，因为命令处理器将它遇到的第二个 % 与它遇到的第一个匹配，但是我们需要在另一个变量表达式中使用一个变量。 (你会看到的。)

此解决方案使用来自 DosTips.com 的 strLen 函数(第 3 行)，可在 Here 中找到.只需将它放入一个名为 strLen.bat 的文件中，就会惊叹于它的速度!

解决方案 1:(FOR/L 解决方案)::首选解决方案::

setlocal ENABLEDELAYEDEXPANSION
set nam=*love*
rem calling strLen
call :strLen nam len
for /l %%x in (0,1,%len%) do if not "!nam:~%%x,1!"=="" if "!nam:~%%x,1!"=="*" (
    set /a plusone=%%x+1
    for /l %%y in (!plusone!, 1, !plusone!) do (
        set nam=!nam:~0,%%x!x!nam:~%%y!
    )
)
echo %nam%
ENDLOCAL

我认为这是一个快速而优雅的解决方案。可以通过将 strLen.bat 的内容添加到例程中来加快速度，但我不想混淆作者。

如果您出于某种原因不想使用 strLen，那么下一个最快的方法可能是使用 GOTO 循环。

解决方案 2:(转到解决方案)

setlocal ENABLEDELAYEDEXPANSION
set nam=*love*
set num=0

:loop
    set /a plusone=%num%+1
    if "!nam:~%num%,1!"=="*" set nam=!nam:~0,%num%!x!nam:~%plusone%!
    set /a num=%num%+1
if not "!nam:~%num%,1!"=="" goto :loop

echo %nam%
EndLocal

特别感谢 dbenham 指出 strLen 函数。它的运行速度比任何基于批处理的函数都快!